3

我还是 Erlang 的新手，并试图让我的头脑无法改变变量。假设我创建了一个堆栈并想要添加一个新元素。如果我无法为列表分配新值，我将如何更新堆栈？我每次都需要创建一个新列表吗？

例如，我在想 Push 可能看起来像

List = [X|List].

然后是流行音乐

[Head|Tail] = List
Head
List = Tail

当然这不起作用，因为我无法更改 List 的值，这是我的问题。任何帮助表示赞赏。

4

2 回答 2

4

Erlang 在函数内部不能有副作用，这是函数式编程语言中常见的特性。更改变量状态是一种副作用。Erlang 中的所有状态变化都被进程和消息传递所隐藏，这就是所谓的参与者模型。

“更改”变量的常用方法是让函数使用更改后的变量调用自身，这称为递归。例如，要对列表的所有元素求和：

sum([]) -> 0;
sum([H|Tail]) -> H + sum(Tail).

更好的是让你的函数尾递归，这意味着它们将自己称为函数体中的最后一条指令。这将节省内存，因为并非所有函数调用都需要保留在堆栈中（尾调用优化）。相同的示例，但使用尾递归：

sum([], Acc) -> Acc;
sum([H|Tail], Acc) -> sum(Tail, Acc + H).

sum(L) -> sum(L, 0).

在这个例子中，我引入了一个累加器变量来传递中间结果。

如何使程序无副作用并不总是显而易见的，尤其是当您尝试以过程术语（如在 C 或 Java 中）来考虑问题时。它需要实践，可能还需要在更理论的层面上理解函数式编程的意愿。

纯粹的函数式编程语言根本不会有任何副作用；函数的返回值必须仅基于函数的输入参数，并且函数的唯一输出必须是返回值。这不是Erlang 的情况。recieve子句和!运算符用于函数内部的输入和输出；副作用。外部状态可以作为可以发送消息和获得回复的进程来保存。

这是一个如何创建一个变量的示例，该变量的值可以通过消息传递来更改（尝试找出是否var_proc是尾递归的！）：

var_proc(Value) ->
    receive
    {get, Pid} ->
            Pid ! {value, Value},
            var_proc(Value);
        {set, New} -> 
            var_proc(New)
    end.

var_start(Init) ->
    spawn(?MODULE, var_proc, [Init]).

var_set(Pid, Value) ->
    Pid ! {set, Value}.

var_get(Pid) ->
    Pid ! {get, self()},
    receive
    {value, Value} -> Value
    end.

这是一个如何使用它的示例（我将模块称为“sum”）：

13> V = sum:var_start(6).
<0.72.0>
14> sum:var_get(V).
6
15> sum:var_set(V, 10).
{set,10}
16> sum:var_get(V).    
10

更多示例和一些动机可以在 Erlang 文档的并发编程章节中找到。

于 2013-02-16T16:18:37.307 回答
3

对于像 Erlang 这样的函数式编程语言中的堆栈数据结构，您通常不会费心创建一个单独的进程来包含消息并对其进行操作，除非您希望多个进程同时访问它。

您应该每次都分配一个新变量，以包含堆栈的修改版本并从那里使用它：

new() -> [].

push(Value, OldStack) -> [Value|OldStack].

pop([]) -> empty;
pop([Value|RestStack]) -> {Value, RestStack}.

你像这样使用它：

S0 = new(),
S1 = push(a, S0),
S2 = push(b, S1),
S3 = push(c, S2),
...
case pop(SN) of
   empty -> stack_was_empty;
   {Element, SN1} ->
     do_something_with(Element),
     SN2 = push(b, SN1),
     ...
...
于 2013-02-17T12:22:08.733 回答