4

我正在中进行一项扫描数字列表的分配，并应返回该列表是否是有效的罗马数字和数字的十进制值。前任）

1 ?- roman(N, ['I'], []).
N = 1
true.

2 ?-

当我运行我认为应该工作的程序时，十进制值总是正确的，所以我猜我得到了合成属性部分是正确的，但是对于应该返回 true 的数字列表，它总是返回 false。我还想补充一点，如果存在超过 3 个 Is、Xs 或 Cs，它应该会中止。

1 ?- roman(N, ['I'], []).
N = 1 ;
false.

2 ?- roman(N, ['I','I','I','I'], []).
Error: too many I's
% Execution Aborted
3 ?-

当我取出 N 并放入 a{write('N = '), write(N)}时，它工作正常并返回true。

1 ?- roman(['I'], []).
N = 1
true.

但是，当我删除{N is ValH + ValT + ValU}它时true，它不再显示十进制值。这是我的代码的第一行（因为这是当前的作业，我希望尽可能少地显示以获得答案）：

roman(N) --> hundreds(ValH), tens(ValT), units(ValU), {N is ValH + ValT + ValU}.

为什么这在 N 时返回 false，但在没有时返回 true，我该如何解决？

赋值： 下面的 BNF 规范定义了小于 1000 的罗马数字的语言：

<roman> ::= <hundreds> <tens> <units>
<hundreds> ::= <low hundreds> | CD | D <low hundreds> | CM
<low hundreds> ::= e | <low hundreds> C
<tens> ::= <low tens> | XL | L <low tens> | XC
<low tens> ::= e | <low tens> X
<units> ::= <low units> | IV | V <low units> | IX
<low units> ::= e | <low units> I

为此语法定义属性以执行两个任务：

a) 限制 X's in <low tens>、 I's in<low units>和 C's in<low hundreds>的数量不超过三个。

b) 提供一个属性，<roman>该属性给出所定义的罗马数字的十进制值。

定义这些任务所需的任何其他属性，但不要更改 BNF 语法。

4

1 回答 1

2

您是否注意到语法是由重复 3 次的相同模式 (group//5) 形成的，只是符号不同？我喜欢紧凑...

roman(N) -->
    group('C','D','M',100, H),
    group('X','L','C',10, T),
    group('I','V','X',1, U),
    {N is H+T+U}.
group(A,B,C, Scale, Value) -->
    (   g3(A, T)
    ;   [A, B], {T = 4}
    % thanks to Daniel and Will for catching bugs
    ;   [B], g3(A, F), {T is 5+F}
    ;   [B], {T is 5}
    ;   [A, C], {T = 9}
    ;   {T = 0}
    ),  {Value is Scale * T}.


g3(C, 1) --> [C].
g3(C, 2) --> [C,C].
g3(C, 3) --> [C,C,C].

一些测试

?- atom_chars('CMXXX',L), phrase(roman(N),L).
L = ['C', 'M', 'X', 'X', 'X'],
N = 930 ;
false.

?- atom_chars('CMXLVIII',L), phrase(roman(N),L).
L = ['C', 'M', 'X', 'L', 'V', 'I', 'I', 'I'],
N = 943 ;
false.

只是好奇，在工作中展示 DCG...

在丹尼尔和威尔评论之后编辑......

?- atom_chars('VIII',L), phrase(roman(N),L).
L = ['V', 'I', 'I', 'I'],
N = 8 .

?- phrase(roman(X), ['L','I','X']).
X = 59 .
于 2013-02-15T23:23:35.730 回答