1

我需要从以下字符串中提取最后一个单词以使用姓氏：

<CUSTOMER_x0020_NAME>Mr Tim Cookson</CUSTOMER_x0020_NAME>

所以我只需要使用 XSLT 拉出“Cookson”，我该怎么做？尝试了几种与 substring-after 的关系，但没有运气。

4

2 回答 2

2

这是一个非递归解决方案，它适用于任何非字母字符的单词分隔符（但最后一个单词之后的字符，如果有的话，应该只是空格）：

<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pLower" select=
  "'abcdefghijklmnopqrstuvwxyz'"/>

 <xsl:param name="pUpper" select=
  "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

 <xsl:variable name="vAlpha" select="concat($pUpper, $pLower)"/>

 <xsl:template match="text()">
  <xsl:variable name="vText" select="normalize-space()"/>
  <xsl:variable name="vLength" select="string-length($vText)"/>
  <xsl:variable name="vPunct" select="translate(., $vAlpha, '')"/>

  <xsl:for-each select=
      "document('')//node()
      |document('')//@*
      |document('')//namespace::*">
   <xsl:variable name="vPos" select="position()"/>
   <xsl:variable name="vRemaining" 
                 select="substring($vText, $vPos)"/>

   <xsl:if test=
    "contains($vPunct, substring($vRemaining,1,1))
    and
     $vLength -$vPos 
       = string-length(translate($vRemaining, $vPunct, ''))
    ">
     <xsl:value-of select="substring($vRemaining,2)"/>
   </xsl:if>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<CUSTOMER_x0020_NAME>Mr Tim Cookson</CUSTOMER_x0020_NAME>

产生了想要的正确结果：

Cookson

在此 XML 文档上应用相同的转换时：

<CUSTOMER_x0020_NAME>Mr. Tim Berners-Lee</CUSTOMER_x0020_NAME>

再次产生正确的结果：

Lee
于 2013-02-14T04:51:21.970 回答
0

您可以使用此递归模板来获取值的最后一个单词：

  <xsl:template name="GetLastWord">
    <xsl:param name="value" />
    <xsl:variable name="normalized" select="normalize-space($value)" />

    <xsl:choose>
      <xsl:when test="contains($normalized, ' ')">
        <xsl:call-template name="GetLastWord">
          <xsl:with-param name="value" select="substring-after($normalized, ' ')" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$normalized"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

您可以将此模板添加到您的 XSLT，然后简单地调用它，如下所示：

  <xsl:call-template name="GetLastWord">
    <xsl:with-param name="value" select="CUSTOMER_x0020_NAME" />
  </xsl:call-template>
于 2013-02-13T18:29:49.563 回答