5

在我的 Fortran 代码中，我想使用具有多级分配的锯齿状数组。我的意思的示例代码是

module nonsquare_matrix_mod
implicit none

   type :: nonsquare_matrix 
      integer :: d
      real*8, dimension(:), allocatable :: vector
   end type nonsquare_matrix

   type(nonsquare_matrix),dimension(:),allocatable :: mymatrix

end module nonsquare_matrix_mod

program nonsquare_matrix_test
   use nonsquare_matrix_mod
   implicit none

integer, parameter :: max_size=50
integer :: i

allocate(mymatrix(max_size))
do i=1,max_size
    allocate(mymatrix(i) % vector(i))
end do

print *, "allocated"


end program

我想实现这种编程策略以节省内存。我知道这个例子中节省的内存不是太大，但是对于我的实际项目，我正在使用更大的数据结构。我想知道这种编程实践是否存在任何危险，例如数据没有连续存储或者更容易出现内存泄漏。或者这是一种节省内存而没有很多缺点的有用方法？谢谢。

4

1 回答 1

6

由于您仅使用可分配数组，因此不会有任何内存泄漏，因为使用指针时可能会出现这种情况。锯齿状数组是否是您问题的合理解决方案在很大程度上取决于您的数据结构。需要注意的几点：

  • 实际上，您的数组不会是连续的。当您访问后续行时，这有几个含义，例如更糟糕的缓存行为。

  • 您必须通过allocate单独分配每一行。如果它经常发生（例如在循环内），那可能是一个问题，因为分配是一个相当“缓慢”的操作。

  • 如果数组中的行的大小确实非常不同（并且您没有太多行），则可以节省大量内存。

如果行的长度是在创建时设置的并且之后没有更改（并且您可以很好地猜测整个数组中最多有多少元素），您可以分配一个大的缓冲区数组，您将在行中，以及一个索引数组，其中包含该行的第一个元素在缓冲区数组中的位置：

 program nonsquare_matrix_test
  implicit none

  integer, parameter :: dp = kind(1.0d0)
  integer, parameter :: maxlines = 50
  integer, parameter :: maxelements = 5000
  real(dp), allocatable :: buffer(:)
  integer, allocatable :: rowindex(:)
  integer :: ii

  allocate(buffer(maxelements))
  allocate(rowindex(maxlines + 1))
  rowindex(1) = 1
  do ii = 1, maxlines
    rowindex(ii + 1)  = rowindex(ii) + ii
  end do
  ! ...  
  ! Omitting the part which fills up the array
  ! ...
  ! Accessing a given line (e.g. line 5)
  print *, "Content of line 5:"
  print *, buffer(rowindex(5):rowindex(6)-1)

end program nonsquare_matrix_test
于 2013-02-13T19:27:52.440 回答