1

所以基本上我需要一个循环遍历 XML 节点的函数，如果条件为真，它将该值添加到变量中。我正在汇总社交帖子，需要计算每个社交帖子中有多少在提要中。这是我的 XML：

 <feed>
   <channel>
     <sources>
       <source>
           <name>Facebook</name>
           <count>3</count>
       </source>
       <source>
           <name>Twitter</name>
           <count>2</count>
       </source>
       <source>
           <name>Twitter</name>
           <count>8</count>
        </source>
     </sources>
   </channel>
  </feed>

问题是同一个来源可以出现多次，我需要将它们加在一起。因此，对于上述 XML，我需要 10 个 twitter 计数。这是我目前所处的位置：

<xsl:variable name="num_tw">
<xsl:for-each select="feed/channel/sources/source">
  <xsl:choose>
    <xsl:when test="name, 'twitter')">
      <xsl:value-of select="count"/>
    </xsl:when>
    <xsl:otherwise></xsl:otherwise>
  </xsl:choose>
</xsl:for-each>
</xsl:variable>

<xsl:variable name="num_fb">
<xsl:for-each select="feed/channel/sources/source">
  <xsl:choose>
    <xsl:when test="name, 'facebook')">
      <xsl:value-of select="count"/>
    </xsl:when>
    <xsl:otherwise></xsl:otherwise>
  </xsl:choose>
</xsl:for-each>
</xsl:variable>

这不起作用，因为如果有两个 twitter 提要，它会将数字并排放置并输出“28”而不是“10”。任何帮助表示赞赏！

4

1 回答 1

4

您不需要在此处使用xsl:for-each遍历节点。相反，您可以使用sum运算符。例如，您的num_tw变量可以像这样重写

<xsl:variable name="num_tw" select="sum(feed/channel/sources/source[name='Twitter']/count)"/>

但是，您真的想在这里硬编码您的提要名称吗？这实际上是一个“分组”问题，在 XSLT 1.0 中，您使用一种称为 Muencian Grouping 的技术来解决它。在您的情况下，您希望按名称元素对源元素进行分组，因此您定义了一个键，如下所示：

<xsl:key name="source" match="source" use="name" />

然后，查看所有源元素，并选择组中第一个作为其给定名称元素的元素：

<xsl:apply-templates 
   select="feed/channel/sources/source[generate-id() = generate-id(key('source', name)[1])]" />

然后，在与此匹配的模板中，您可以像这样总结计数：

<xsl:value-of select="sum(key('source', name)/count)" />

这是完整的 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:key name="source" match="source" use="name" />

    <xsl:template match="/">
    <xsl:apply-templates select="feed/channel/sources/source[generate-id() = generate-id(key('source', name)[1])]" />

    </xsl:template>

    <xsl:template match="source">
        <source>
            <xsl:copy-of select="name" />
            <count><xsl:value-of select="sum(key('source', name)/count)" /></count>
        </source>
    </xsl:template>
</xsl:stylesheet>

当应用于您的 XML 时，将输出以下内容：

<source>
   <name>Facebook</name>
   <count>3</count>
</source>
<source>
   <name>Twitter</name>
   <count>10</count>
</source>

请注意，如果您确实想了解特定提要的计数，例如“Facebook”，则最好在此处使用密钥。例如：

<xsl:variable name="num_fb" select="sum(key('source', 'Facebook')/count)"/>
于 2013-02-11T20:17:13.510 回答