0

原始数据集如下：

sub month y
1   1     1
1   2     2
1   3     3
1   5     5

我想要的是根据每个主题的月份获得前 3 年，如果 y 在那个月缺失，那么新变量也是.如此。比如说，对于上面的例子，lag1 是y上个月的previous，lag2是2 个月前的previous y，lag3到目前为止是这样：

sub month y lag1 lag2 lag3
1   1     1  .    .    .
1   2     2  1    .    .
1   3     3  2    1    .
1   5     5  .    3    2

问题是我检查了lag功能dif，但在我的情况下，我想要的lag取决于month月份之间也有差距，所以我不能使用前一个类似的lag1功能。

我也需要为许多科目做这个。谢谢。

4

1 回答 1

2

SQL解决方案：

data have;
input sub month y;
datalines;
1   1     1
1   2     2
1   3     3
1   5     5 
;;;;
run;

proc sql;
create table want as
    select H.sub,H.month, H.y, One.y as lag1, Two.y as lag2, Three.y as lag3
    from have H
    left join (select * from have) One on H.sub=One.sub and H.month=One.month+1
    left join (select * from have) Two on H.sub=two.sub and H.month=Two.month+2
    left join (select * from have) Three on H.sub=three.sub and H.month=Three.month+3
;
quit;

显然，如果你想要其中的 36 个，这会有点长，但至少不是那么复杂。还有各种其他方法可以做到这一点。不要使用 LAG，这会让人头疼，而且无论如何都不合适。如果您熟悉哈希的概念，哈希表可能更有效并且需要更少的编码。

哈希解决方案：

data want;
if _n_ = 1 then do;
 declare hash h(dataset:'have(rename=y=ly)');
 h.defineKey('sub','month');
 h.defineData('ly');
 h.defineDone();
 call missing(sub,month,ly);
end;
set have;
array lags lag1-lag3;
do prevmonth = month-1 to month-3 by -1;
  if prevmonth le 0 then leave;
  rc=h.find(key:sub,key:prevmonth);
  if rc=0 then lags[month-prevmonth] = ly;
  call missing(ly);
end;
run;

这非常简单，可以扩展到 36 [或其他] - 只需将数组的长度更改为array lags lag1-lag36和 do 语句do prevmonth=month-1 to month-36 by -1; 您可能需要做的大部分工作就是安排事情，以便月份在这里工作 - 通过创建一个整数月份，或者更改循环标准以使用月/年或诸如此类的东西。您没有显示您的数据是如何指定的，因此无法提供帮助。

于 2013-02-08T22:11:10.667 回答