8

我想创建一个表单，给定它的类名作为字符串，之前已经问过这个问题，但我不想调用GetClass，而是想使用 Delphi 的新 RTTI 功能。

使用此代码，我有一个TRttiType，但我不知道如何实例化它。

var
  f:TFormBase;
  ctx:TRttiContext;
  lType:TRttiType;
begin
  ctx := TRttiContext.Create;
  for lType in ctx.GetTypes do
  begin
    if lType.Name = 'TFormFormulirPendaftaran' then
    begin
      //how to instantiate lType here?
      Break;
    end;
  end;
end;

我也试过lType.NewInstance没有运气。

4

2 回答 2

11

您必须将TRttiType转换为TRttiInstanceType类，然后使用该函数调用构造GetMethod函数。

试试这个样本

var
  ctx:TRttiContext;
  lType:TRttiType;
  t : TRttiInstanceType;
  f : TValue;
begin
  ctx := TRttiContext.Create;
  lType:= ctx.FindType('UnitName.TFormFormulirPendaftaran');
  if lType<>nil then
  begin
    t:=lType.AsInstance;
    f:= t.GetMethod('Create').Invoke(t.MetaclassType,[nil]);
    t.GetMethod('Show').Invoke(f,[]);
  end;
end;
于 2013-02-07T03:00:46.197 回答
4

您应该使用该TRttiContext.FindType()方法而不是手动遍历TRttiContext.GetTypes()列表，例如：

lType := ctx.FindType('ScopeName.UnitName.TFormFormulirPendaftaran');
if lType <> nil then
begin
  ...
end;

但无论哪种方式，一旦你找到TRttiType了所需的类类型，你就可以像这样实例化它：

type
  TFormBaseClass = class of TFormBase;

f := TFormBaseClass(GetTypeData(lType.Handle)^.ClassType).Create(TheDesiredOwnerHere);

或者这个，如果TFormBase来自TForm：

f := TFormClass(GetTypeData(lType.Handle)^.ClassType).Create(TheDesiredOwnerHere);

或者这个，如果TFormBase来自TCustomForm：

f := TCustomFormClass(GetTypeData(lType.Handle)^.ClassType).Create(TheDesiredOwnerHere);

更新：或者，像@RRUZ 显示的那样做。那是更TRttiType面向的，并且不依赖于使用旧TypInfo单元的功能。

于 2013-02-07T03:02:07.403 回答