6

另一个综合基准：埃拉托色尼筛

C++

#include <vector>
#include <cmath>

void find_primes(int n, std::vector<int>& out)
{
   std::vector<bool> is_prime(n + 1, true);
   int last = sqrt(n);
   for (int i = 2; i <= last; ++i)
   {
      if (is_prime[i])
      {
         for (int j = i * i; j <= n; j += i)
         {
            is_prime[j] = false;
         }
      }
   }

   for (unsigned i = 2; i < is_prime.size(); ++i)
   {
      if (is_prime[i])
      {
         out.push_back(i);
      }
   }
}

OCaml（使用Jane Street 的 Core和Res库）

open Core.Std
module Bits = Res.Bits
module Vect = Res.Array

let find_primes n =
  let is_prime = Bits.make (n + 1) true in
  let last = float n |! sqrt |! Float.iround_exn ~dir:`Zero in
  for i = 2 to last do
    if not (Bits.get is_prime i) then () else begin
      let j = ref (i * i) in
      while !j <= n; do
        Bits.set is_prime !j false;
        j := !j + i;
      done;
    end;
  done;
  let ar = Vect.empty () in
  for i = 2 to n do
    if Bits.get is_prime i then Vect.add_one ar i else ()
  done;
  ar

我很惊讶 OCaml 版本（本机）比 C++ 慢 13 倍。我替换Res.Bits为Core_extended.Bitarray，但它变得慢了约 18 倍。为什么这么慢？OCaml 不为位操作提供快速操作吗？有没有其他快速实现位数组的方法？

需要明确的是：我来自 C++ 世界，并考虑将 OCaml 作为编写性能关键代码的可能替代方案。实际上，我对这样的结果有点害怕。

编辑：

分析结果

Each sample counts as 0.01 seconds.
  %   cumulative   self              self     total           
 time   seconds   seconds    calls  ms/call  ms/call  name    
 50.81      1.26     1.26                             camlRes__pos_1113
  9.72      1.50     0.24                             camlRes__unsafe_get_1117
  6.68      1.66     0.17                             camlRes__unsafe_set_1122
  6.28      1.82     0.16                             camlNopres_impl__set_1054
  6.07      1.97     0.15                             camlNopres_impl__get_1051
  5.47      2.10     0.14 47786824     0.00     0.00  caml_apply3
  3.64      2.19     0.09 22106943     0.00     0.00  caml_apply2
  2.43      2.25     0.06   817003     0.00     0.00  caml_oldify_one
  2.02      2.30     0.05        1    50.00   265.14  camlPrimes__find_primes_64139
  1.21      2.33     0.03                             camlRes__unsafe_get_1041
...
4

4 回答 4

4

在使用复杂的数据结构之前，您是否尝试过先使用简单的数据结构？

在我的机器上，以下代码仅比 C++ 版本慢 4 倍（请注意，我做了最小的更改以使用数组作为缓存，并使用列表来累积结果；您可以使用数组 get/set 语法糖）：

let find_primes n =
  let is_prime = Array.make (n + 1) true in
  let last = int_of_float (sqrt (float n)) in
  for i = 2 to last do
    if not (Array.get is_prime i) then () else begin
      let j = ref (i * i) in
      while !j <= n; do
        Array.set is_prime !j false;
        j := !j + i;
      done;
    end;
  done;
  let ar = ref [] in
  for i = 2 to n do
    if Array.get is_prime i then ar := i :: !ar else ()
  done;
  ar

（慢 4 倍：计算 10_000_000 个第一个素数需要 4 秒，而代码中的 g++ -O1 或 -O2 需要 1 秒）

意识到您的位向量解决方案的效率可能来自经济的内存布局，我将代码更改为使用字符串而不是数组：

let find_primes n =
  let is_prime = String.make (n + 1) '0' in
  let last = int_of_float (sqrt (float n)) in
  for i = 2 to last do
    if not (String.get is_prime i = '0') then () else begin
      let j = ref (i * i) in
      while !j <= n; do
        String.set is_prime !j '1';
        j := !j + i;
      done;
    end;
  done;
  let ar = ref [] in
  for i = 2 to n do
    if String.get is_prime i = '0' then ar := i :: !ar else ()
  done;
  ar

现在只需要 2 秒，这使得它比您的 C++ 解决方案慢 2 倍。

于 2013-02-06T20:23:18.227 回答
3

像这样比较微基准并不经常有用，但基本结论可能是正确的。这是 OCaml 处于明显劣势的情况。C++ 可以访问或多或少的理想表示（机器整数向量）。OCaml 可以生成向量，但不能直接获取机器整数。所以 OCaml 必须使用 div 和 mod，而 C++ 可以使用 shift 和 mask。

我重现了这个测试（使用不同的位向量库），发现 OCaml 中相当多的时间用于构建结果，而不是位数组。因此，测试可能无法准确衡量您的想法。

更新

我尝试了一些快速测试，将 32 个布尔值打包成 63 位整数。它似乎确实让事情进展得更快，但只是一点点。这不是一个完美的测试，但它表明 Gasche 是正确的，非 2 的幂效应很小。

于 2013-02-06T18:14:20.027 回答
3

杰弗里斯科菲尔德似乎是对的。这种可怕的性能下降是由于div和mod操作。

我原型化了小Bitarray模块

module Bitarray = struct
  type t = { len : int; buf : string }

  let create len x =
    let init = (if x = true then '\255' else '\000') in
    let buf = String.make (len / 8 + 1) init in
    { len = len; buf = buf }

  let get t i =
    let ch = int_of_char (t.buf.[i lsr 3]) in
    let mask = 1 lsl (i land 7) in
    (ch land mask) <> 0

  let set t i b =
    let index = i lsr 3 in
    let ch = int_of_char (t.buf.[index]) in
    let mask = 1 lsl (i land 7) in
    let new_ch = if b then (ch lor mask) else (ch land lnot mask) in
    t.buf.[index] <- char_of_int new_ch
end

它使用字符串作为字节数组（每个字符 8 位）。最初我使用x / 8andx mod 8进行位提取。它比 C++ 代码慢 10 倍。然后我用x lsr 3and替换了它们x land 7。现在，它只比 C++ 慢 4 倍。

于 2013-02-06T23:44:45.020 回答
1

请确保您安装的 Core 包含 .cmx 文件（.cmxa 还不够！），否则跨模块内联将不起作用。您的个人资料表明某些调用可能没有被内联，这可以解释效率的巨大损失。

遗憾的是，许多 OCaml 项目使用的 Oasis 打包工具目前存在一个错误，阻止它安装 .cmx 文件。Core 包也受到此问题的影响，可能与您使用的包管理器（Opam、Godi）无关。

于 2013-02-12T17:58:05.623 回答