list - 如何按给定顺序对列表进行排序？

Question

我正在尝试执行以下操作。我有一个预定义的列表，用作给定列表上的“排序依据”。

my @orderby = ( 'car', 'boat', 'chicken', 'cat', 'dog', 'mouse');
   or
my %orderby = ( 'car' => 0, 'boat' => 1, 'chicken' => 2, 'cat' => 3, 'dog' => 4, 'mouse' => 5);

my @list = ('boat', 'car', 'mouse', 'chicken');

我尝试了无数种方法对其进行排序，但没有得到我想要的。我在谷歌和这里搜索过，但我没有找到答案。

@list需要以这种方式排序：

sort @list using %orderby

排序后我想要的打印：

car, boat, chicken, mouse 

顺便说一句，@list 可以有重复的条目：

my @list = ('boat', 'car', 'mouse', 'chicken', 'mouse', 'car');

在这种情况下，打印需要是：

car, car, boat, chicken, mouse, mouse

你们有解决方案吗？或者可能是另一种方法。谢谢！！

Answer 1

my @orderby = qw( car boat chicken cat dog mouse );
my @list    = qw( boat car mouse chicken );

my %orderby = map { $orderby[$_] => $_ } 0..$#orderby;

my @sorted = sort { $orderby{$a} <=> $orderby{$b} } @list;

---

或者如果你想扰乱人们的思想，

my @orderby = qw( car boat chicken cat dog mouse );
my @list    = qw( boat car mouse chicken );

my %counts; ++$counts{$_} for @list;
my @sorted = map { ($_) x ($counts{$_}||0) } @orderby;

Answer 2

当然，如果您有一个按顺序排列的所有潜在项目的列表，以及一个较小的要选择的项目列表，那么这实际上是一个选择问题，而不是排序问题？

my %items = map { $_ => 1 } @list;
my @items = grep { $items{$_} } @orderby;

运行时间为 O(n) 而不是 O(n log n) :)

Answer 3

对于这种情况，基数排序是一个不错的选择：

use Sort::Key::Radix qw(ukeysort);
@sorted = ukeysort { $orderby{$_} } @data;