53

我有一个从 shell 脚本中调用的 SQL 脚本，需要很长时间才能运行。它目前包含dbms_output.put_line不同点的声明。这些打印语句的输出出现在日志文件中，但仅在脚本完成后才会出现。

有什么方法可以确保在脚本运行时输出出现在日志文件中？

4

6 回答 6

62

并不真地。DBMS_OUTPUT 的工作方式是这样的：您的 PL/SQL 块在数据库服务器上执行，不与客户端交互。因此，当您调用 PUT_LINE 时，它只是将该文本放入服务器内存中的缓冲区中。当您的 PL/SQL 块完成时，控制权返回给客户端（在这种情况下我假设 SQLPlus）；此时，客户端通过调用 GET_LINE 将文本从缓冲区中取出并显示出来。

因此，使输出更频繁地出现在日志文件中的唯一方法是将一个大的 PL/SQL 块分解为多个较小的块，以便更频繁地将控制权返回给客户端。这可能不切实际，具体取决于您的代码在做什么。

其他替代方法是使用 UTL_FILE 写入文本文件，您可以随时刷新该文件，或者使用自治事务过程将调试语句插入数据库表并在每个语句之后提交。

于 2009-09-24T16:06:19.317 回答
14

如果可能的话，您应该用您自己的函数替换对 dbms_output.put_line 的调用。

这是此功能的代码WRITE_LOG ——如果您希望能够在 2 个日志记录解决方案之间进行选择：

将日志写入自治事务中的表

CREATE OR REPLACE PROCEDURE to_dbg_table(p_log varchar2)
  -- table mode: 
  -- requires
  -- CREATE TABLE dbg (u varchar2(200)   --- username
  --                 , d timestamp       --- date
  --                 , l varchar2(4000)  --- log 
  -- );
AS
   pragma autonomous_transaction;
BEGIN
  insert into dbg(u, d, l) values (user, sysdate, p_log);
  commit;
END to_dbg_table;
/

或直接写入托管数据库的数据库服务器

这使用Oracle 目录 TMP_DIR

CREATE OR REPLACE PROCEDURE to_dbg_file(p_fname varchar2, p_log varchar2)
  -- file mode: 
  -- requires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
  l_file utl_file.file_type;
BEGIN
  l_file := utl_file.fopen('TMP_DIR', p_fname, 'A');
  utl_file.put_line(l_file, p_log);
  utl_file.fflush(l_file);
  utl_file.fclose(l_file);
END to_dbg_file;
/


WRITE_LOG

然后WRITE_LOG可以在两种使用之间切换的程序，或者被禁用以避免性能损失（g_DEBUG:=FALSE）。

CREATE OR REPLACE PROCEDURE write_log(p_log varchar2) AS
  -- g_DEBUG can be set as a package variable defaulted to FALSE
  -- then change it when debugging is required
  g_DEBUG boolean := true;
  -- the log file name can be set with several methods...
  g_logfname varchar2(32767) := 'my_output.log';
  -- choose between 2 logging solutions:
  -- file mode: 
  g_TYPE varchar2(7):= 'file';
  -- table mode: 
  --g_TYPE varchar2(7):= 'table';
  -----------------------------------------------------------------
BEGIN
  if g_DEBUG then
    if g_TYPE='file' then
      to_dbg_file(g_logfname, p_log);
    elsif g_TYPE='table' then
      to_dbg_table(p_log);
    end if;
  end if;  
END write_log;
/

以下是如何测试上述内容：

1）从你的 SQLPLUS启动这个（文件模式）：

BEGIN
  write_log('this is a test');
  for i in 1..100 loop
    DBMS_LOCK.sleep(1);
    write_log('iter=' || i);
  end loop;
  write_log('test complete');
END;
/

2）在数据库服务器上，打开一个shell和

    tail -f -n500 /directory/where/oracle/can/write/on/DB_server/my_output.log
于 2016-08-23T15:19:18.253 回答
8

两种选择：

  1. 您可以使用自治事务将您的日志记录详细信息插入到日志记录表中。您可以在另一个 SQLPLUS/Toad/sql 开发人员等...会话中查询此日志记录表。您必须使用自治事务才能提交日志记录，而不会干扰主 sql 脚本中的事务处理。

  2. 另一种选择是使用返回日志信息的流水线函数。有关示例，请参见此处：http: //berxblog.blogspot.com/2009/01/pipelined-function-vs-dbmsoutput.html当您使用流水线函数时，您不必使用另一个 SQLPLUS/Toad/sql 开发人员等... 会议。

于 2009-09-25T07:00:35.350 回答
3

调用DBMS_OUTPUT过程时读取的缓冲区。DBMS_OUTPUT.get_line如果您的客户端应用程序是 SQL*Plus，这意味着它只会在过程完成后才被刷新。

您可以应用此 SO中描述的方法将缓冲区写入DBMS_OUTPUT文件。

于 2009-09-24T16:04:29.413 回答
3

dbms_application_info()使用.设置会话元数据 MODULE 和/或 ACTION
使用 OEM 进行监控，例如：

Module: ArchiveData
Action: xxx of xxxx
于 2019-10-08T21:42:38.293 回答
0

如果您可以从 PL/SQL 环境访问系统 shell，则可以调用 netcat：

 BEGIN RUN_SHELL('echo "'||p_msg||'" | nc '||p_host||' '||p_port||' -w 5'); END;

p_msg- 日志消息 v_host是主机运行 python 脚本，从端口上的套接字读取数据v_port。

我在编写用于实时 shell 和 pl/sql 日志监控的aplogr时使用了这种设计。

于 2017-11-27T19:20:13.707 回答