2

有人可以告诉我如何在 Prolog 中找到列表的模式吗？

我试过这个：

count_elt([], _, 0) :- !. 
count_elt([H|T], H, P) :- 
  count_elt(T, H, P1),
  P is P1 + 1, !. 
count_elt([_|T], E, P) :- count_elt(T, E, P). 

listMode([], 0) :- !. 
listMode([_], 1) :- !. 
listMode([H1|[H2|T]], M) :- 
  count_elt([H1|[H2|T]], H1, C),
  listMode([H2|T], C1),
  C > C1,
  M is C, !. 
listMode([_|[H2|T]], M) :- listMode([H2|T], M).

它只返回列表中出现的最多次数。但我需要返回出现次数最多的元素（列表中最频繁的值）。

4

3 回答 3

3

您实际上与 非常接近count_elt/3，但您需要更多的非确定性。简而言之，你需要找到一种count_elt/3减少剪辑的方式来表达，因为现在你得到了这个：

?- count_elt([a,b,a,a,c,b,d,e,a,f], Y, X).
Y = a,
X = 4.

而你想要得到的是：

?- count_elt([a,b,a,a,c,b,d,e,a,f], Y, X).
Y = a,
X = 4 ;
Y = b,
X = 2 ;
Y = c,
X = 1 ;
...
Y = f,
X = 1 ;
false.

从那里您只是试图找到具有最大值的解决方案，您可以使用setof/3逻辑表达式或使用aggregate库来完成。所以首先修复count_elt/3并从那里开始。

编辑：一些一般性评论：

  • 你可以写成[H1|[H2|T]]，[H1,H2|T]这样更清楚一点。
  • listMode/2可能应该将项目返回第二个位置而不是计数。由于您需要计数来执行此过程，因此您可能需要创建一个listMode/3或listMode/5帮助程序来在递归期间管理您的状态。

编辑：解决方案

由于@MaDu_LK 决定展示解决方案，即使这很可能是家庭作业，我想我会分享我的，使用@false 的具体化相等谓词：

count_of([],         _,  0).
count_of([H|Rest], E, N1) :- 
  equality_reified(H, E, Bool),
  count_of(Rest, E, N0),
  (Bool == true -> N1 is N0 + 1 ; N1 = N0).

frequency(L, I, N) :-
  sort(L, LSorted),
  member(I, LSorted),
  count_of(L, I, N).

mode(L, X) :-
  frequency(L, X, NMax),
  \+ (frequency(L, _, NBigger),
      NMax < NBigger).

这具有更令人愉悦的性能特性：

% MaDu_LK
?- time(get_mode([a,b,c,a,b,c,a,a,b,c,a,d,b], X)).
% 2,811 inferences, 0.000 CPU in 0.000 seconds (100% CPU, 7117429 Lips)
X = a.

% mine
?- time(mode([a,b,c,a,b,c,a,a,b,c,a,d,b], X)).
% 217 inferences, 0.000 CPU in 0.000 seconds (98% CPU, 3144928 Lips)
X = a ;
% 195 inferences, 0.000 CPU in 0.000 seconds (97% CPU, 3305085 Lips)
false.

即使列表是多模式的，另一种解决方案也只产生一种模式：

% MaDu_LK
?- get_mode([a,a,b,b,c], X).
X = a.

% mine
?- mode([a,a,b,b,c], X).
X = a ;
X = b ;
false.

深思熟虑。

于 2013-02-04T17:26:01.270 回答
1

你已经从 Daniel 那里得到了关于你的代码的好建议。我将展示一种获取信息的库（聚合）替代方法：

mode_of_list(L, M) :-
    setof(C-E, (member(E, L), aggregate(count, member(E, L), C)), M).

测试

?- mode_of_list([a,b,a,a,c,b,d,e,a,f],L).
L = [1-c, 1-d, 1-e, 1-f, 2-b, 4-a].
于 2013-02-04T18:03:16.143 回答
-1

希望你已经得到了一些建议。这是适合您的工作代码。 

count_elt([],_,0):-!.
count_elt([H|T],H,C):-count_elt(T,H,C1),C is C1+1,!.
count_elt([_|T],E,C):-count_elt(T,E,C).

listMode([],0) :- !.
listMode([_],1) :- !.
listMode([H1|[H2|T]], M) :-count_elt([H1|[H2|T]],H1,C),listMode([H2|T],C1),C > C1,M is C,!.
listMode([_|[H2|T]],M) :- listMode([H2|T],M).

get_mode([H|T],M):-listMode([H|T],K),count_elt([H|T],M,K).
于 2013-02-05T01:34:43.613 回答