prolog - 如何在 Prolog 中找到目标的所有解决方案？

Question

我有谓词 P1 一个接一个地返回值，如下所示：

-? P1(ARGUMENTS, RETURN).
-? RETURN = 1;
-? RETURN = 2;
-? RETURN = 3;
-? fail.

我还有另一个谓词 P2：

P2(ARGUMENTS, LIST) :- P1(ARGUMENTS, RETURN),... % SOMEHOW HERE I NEED TO INSERT ALL VALUES OF RETURN TO LIST.

如何找到 的所有值RETURN并将它们分配给LIST？

Answer 1

用于findall完成此操作：

P2(ARGUMENTS, LIST) :- findall(X, P1(ARGUMENTS, X), LIST).

这与Anders Lindahl 链接bagof的问题中提到的功能有关。这里setof对这两个函数（和第三个函数）之间的关系有一个很好的解释：

为了说明差异，请考虑一个小例子：

listing(p).

p(1,3,5).
p(2,4,1).
p(3,5,2).
p(4,3,1).
p(5,2,4).

尝试以下目标。（答案显示已修改以节省空间。）

?- bagof(Z,p(X,Y,Z),Bag).
Z = _G182 X = 1 Y = 3 Bag = [5] ;
Z = _G182 X = 2 Y = 4 Bag = [1] ;
Z = _G182 X = 3 Y = 5 Bag = [2] ;
Z = _G182 X = 4 Y = 3 Bag = [1] ;
Z = _G182 X = 5 Y = 2 Bag = [4] ;
No

?- findall(Z,p(X,Y,Z),Bag).
Z = _G182 X = _G180 Y = _G181 Bag = [5, 1, 2, 1, 4] ;
No

?- bagof(Z,X^Y^p(X,Y,Z),Bag).
Z = _G182 X = _G180 Y = _G181 Bag = [5, 1, 2, 1, 4] ;
No

?- setof(Z,X^Y^p(X,Y,Z),Bag).
Z = _G182 X = _G180 Y = _G181 Bag = [1, 2, 4, 5] ;
No

目标中自由变量的单个绑定的谓词bagof和setof产生集合。setof 生成没有重复的集合的排序版本。为避免绑定变量，请使用存在量词表达式。例如，目标 bagof(Z,X^Y^p(X,Y,Z),Bag)要求“的 Bag ofZ存在一个X并且存在一个Y这样的 p(X,Y,Z)”。findall就像bagof 所有自由变量自动存在量化一样。此外 findall返回一个空列表[]，没有目标满足，而bagof 失败。