windows - Windows Batch：使用文件夹中的所有文件执行应用程序，随机排序

Question

我使用媒体播放器经典播放视频。我可以制作一个批处理文件来播放播放列表，如下所示：

mpc.exe video1.avi video2.avi video3.avi ...

有用。

现在我想制作一个批处理文件，播放随机排序的文件夹中的所有视频。

任何想法？

谢谢

Answer 1

下面的代码假定您正在播放当前目录中的文件，并且假定您的 .avi 文件名都不是以=. 消除这些限制并不需要太多。

如果您的文件夹中有太多文件，那么最终命令长度将超过允许的最大长度 8191 字节。

@echo off
setlocal disableDelayedExpansion
for /f "delims==" %%A in ('set file. 2^>nul') do set "%%A="
for /f "tokens=1* delims=:" %%A in (
  'dir /b /a-d *.avi^|findstr /n "^"'
) do (
  set "file.%%A=%%B"
  set "cnt=%%A"
)
set "cmd=mpc.exe"
for /l %%N in (%cnt% -1 1) do call :buildCmd %%N
%cmd%
exit /b

:buildCmd
set /a N=%random% %% %1
set "skip="
if %N% gtr 0 set "skip=skip=%N%"
for /f "%skip% tokens=1* delims==" %%A in ('set file.') do (
  set cmd=%cmd% "%%B"
  set "%%A="
  exit /b
)

Answer 2

The Batch file below will fail if the name of any video file have exclamation marks. This may be fixed, if needed.

@echo off
setlocal EnableDelayedExpansion

rem Store the file names into an array
set cnt=0
for %%a in (*.avi) do (
   set /A cnt+=1
   set file[!cnt!]=%%a
)

rem Insert the names in the command line in random order
set cmd=mpc.exe
for /L %%a in (%cnt%,-1,1) do (
   set /A i=%%a*!random!/32768+1
   for %%i in (!i!) do set cmd=!cmd! "!file[%%i]!"
   set file[%%i]=!file[%%a]!
)

%cmd%

Antonio