4

在 perl 中，有一种方法可以从文本文件中传递的日期中减去 10 天，并且输出应为 01-jan-1999 格式。

我正在使用下面的代码来读取文件并获取日期，之后我对减去日期感到震惊。

日期.txt

2013 年 1 月 25 日

#!/usr/bin/perl
use warnings;
use strict;
use DateTime;

my $inp= "date.txt";
my $todate;
my $fromdate;

open(date,"$inp");
while(<date>)
{
$todate = $_ ;
print "$todate \n";
}

$fromdate = $todate - 10 days ;
4

3 回答 3

9

这是一个使用 DateTime 的答案。

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

use DateTime::Format::Strptime;
use DateTime;

my $parser = DateTime::Format::Strptime->new(
  pattern => '%d-%B-%Y'
);

my $input = '25-jan-2013';

my $todate = $parser->parse_datetime($input);

my $fromdate = $todate->clone;
$fromdate->subtract(days => 10);
say 'From: ', $fromdate->strftime('%d-%B-%Y');
say 'To: ', $todate->strftime('%d-%B-%Y');
于 2013-02-02T21:28:09.477 回答
3

在过去，您会使用Time::Local将您的时间转换为自 Epoc 以来的秒数，减去十天的秒数 (10 * 24 * 60 * 60)，然后将其转换回使用localtime的时间。这很有趣，很有教育意义，而且大多数情况下，它过于复杂且容易出错。

当我能够使用 Perl 5.10 或更高版本时，我更喜欢使用Time::Piece，因为它使事情变得简单，而且最重要的是，它是一个标准的 Perl 模块。另外，它与另一个标准 Perl 模块Time::Seconds配合得很好：

use warnings;
use strict;
use autodie;
use feature qw(say);

use Time::Piece;
use Time::Seconds;

my $date = "25-jan-2013";

#Create the "date object". The `%d-%b-%Y" is format the date is in
my $my_date = Time::Piece->strptime($date, "%d-%b-%Y");  #

#Now subtract ten days from it
$my_date -= ( 10 * ONE_DAY );  #Constant from Time::Seconds

say $my_date;   #Prints out Tue Jan 15 00:00:00 2013

#Printing it out in dd-mmm-yyyy format you had
say $my_date->mday . "-" . $my_date->monname . "-" . $my_date->year;
于 2013-07-11T18:50:58.220 回答
1

您可以使用Date::Manip：

#!/usr/bin/perl
use warnings;
use strict;

use Date::Manip;

my $todate  = '25-jan-2013';
my $newdate = DateCalc(ParseDate($todate), ParseDateDelta('- 10 days'));

print "$newdate\n";
于 2013-02-01T10:11:11.493 回答