1

我正在尝试使用一个名为 webcrtl 的 Inno 设置插件（一个比 nsweb 具有更多功能的网络浏览器）。我正在尝试使用系统插件调用此 dll。

插件：

http://restools.hanzify.org/article.asp?id=90

这就是我正在尝试的，但没有成功：

Page custom Pre

Var hCtl_dialog
Var browser
Function Pre
    InitPluginsDir
    File "${BASEDIR}/Plugins/inno_webctrl_v2.1/webctrl.dll"

    nsDialogs::Create 1018
    Pop $hCtl_dialog

    System::Call "webctrl::NewWebWnd(i $HWNDPARENT, i 100, i 100, i 200, i 200) i .s"
    Pop $browser
    System::Call "webctrl::DisplayHTMLPage(i '$browser', t  'http://www.google.com/') i .s"
    Pop $R0

    nsDialogs::Show $hCtl_neoinstaller_genericcustom
FunctionEnd

我得到一个空页面...

4

1 回答 1

2

DLL 库函数名称区分大小写，并且您使用了别名而不是该 InnoSetup 脚本中的函数名称。修改您的脚本，以便使用具有适当大小写敏感性的函数名称，您将让您的脚本正常工作。要导入的函数的名称是关键字 import tail中@字符之前的单词。external例如，在以下函数导入示例中，导入函数的名称是newwebwnd，而不是NewWebWnd：

function NewWebWnd(hWndParent: HWND; X, Y, nWidth, nHeight: Integer): HWND;
  external 'newwebwnd@files:webctrl.dll stdcall';

因此，在您的情况下，请按以下方式修改函数名称，您应该没问题：

...
  System::Call "webctrl::newwebwnd(i $hCtl_dialog, i 0, i 0, i 150, i 150) i.s"
  Pop $browser
  System::Call "webctrl::displayhtmlpage(i $browser, t 'http://www.google.com/') b.s"
  Pop $R0
...

在安装页面中拉伸的控件的整个脚本WebCtrl可能如下所示：

!include "nsDialogs.nsh"

OutFile "Setup.exe"
RequestExecutionLevel user
InstallDir $DESKTOP\WebBrowserSetup

Page directory
Page custom InitializeWebBrowserPage

var hDialog
var hBrowser
Function InitializeWebBrowserPage

    InitPluginsDir
    SetOutPath $PLUGINSDIR
    File "webctrl.dll"

    nsDialogs::Create 1018
    Pop $hDialog

    ; get the page client width and height
    System::Call "*(i, i, i, i) i.r0"
    System::Call "user32::GetClientRect(i $hDialog, i r0)"
    System::Call "*$0(i, i, i.r1, i.r2)"
    System::Free $0

    ; create a web browser window stretched to the whole page client rectangle
    ; and navigate somehwere; note that you should add some error handling yet
    System::Call "webctrl::newwebwnd(i $hDialog, i 0, i 0, i $1, i $2) i.s"
    Pop $hBrowser
    System::Call "webctrl::displayhtmlpage(i $hBrowser, t 'http://www.google.com') b.s"
    Pop $R0

    nsDialogs::Show

FunctionEnd

Section ""
SectionEnd
于 2013-02-01T04:02:59.080 回答