excel - 循环遍历 Excel 中范围的每一行

Question

这是我确信有一个内置函数的事情之一（过去我可能已经被告知过），但我正在挠头来记住它。

如何使用 Excel VBA 遍历多列范围的每一行？我一直在搜索的所有教程似乎都只提到了通过一维范围工作......

Answer 1

Dim a As Range, b As Range

Set a = Selection

For Each b In a.Rows
    MsgBox b.Address
Next

Answer 2

像这样的东西：

Dim rng As Range
Dim row As Range
Dim cell As Range

Set rng = Range("A1:C2")

For Each row In rng.Rows
  For Each cell in row.Cells
    'Do Something
  Next cell
Next row

Answer 3

只是偶然发现了这一点，并认为我会提出我的解决方案。我通常喜欢使用将范围分配给多维数组的内置功能（我猜它也是我的 JS 程序员）。

我经常写这样的代码：

Sub arrayBuilder()

myarray = Range("A1:D4")

'unlike most VBA Arrays, this array doesn't need to be declared and will be automatically dimensioned

For i = 1 To UBound(myarray)

    For j = 1 To UBound(myarray, 2)

    Debug.Print (myarray(i, j))

    Next j

Next i

End Sub

为变量分配范围是在 VBA 中操作数据的一种非常强大的方法。

Answer 4

在 Loops 中，我总是喜欢使用Cells类，使用 R1C1 引用方法，如下所示：

Cells(rr, col).Formula = ...

这使我能够轻松快速地循环遍历一系列单元格：

Dim r As Long
Dim c As Long

c = GetTargetColumn() ' Or you could just set this manually, like: c = 1

With Sheet1 ' <-- You should always qualify a range with a sheet!

    For r = 1 To 10 ' Or 1 To (Ubound(MyListOfStuff) + 1)

        ' Here we're looping over all the cells in rows 1 to 10, in Column "c"
        .Cells(r, c).Value = MyListOfStuff(r)

        '---- or ----

        '...to easily copy from one place to another (even with an offset of rows and columns)
        .Cells(r, c).Value = Sheet2.Cells(r + 3, 17).Value


    Next r

End With