2

我已经玩了几个小时了，离解决方案还差得远。

当我通过以下方式创建数组时，它会毫无困难地输出到一个范围：

Dim Destination As Range
Set Destination = NewSheet.Range("A1")

ReDim OutArray(1 To 1, 1 To NumArrayCols) As Variant
OutArray(1, 1) = "hello"
Destination.Resize(UBound(OutArray, 1), UBound(OutArray, 2)).Value = OutArray

但是，当我以以下方式创建输出数组时，它只是将一个大的空白数组粘贴到我的电子表格中。代码的第一部分可能几乎无关紧要，但我想包括它以防我遗漏任何东西：

ReDim OutArray(1, 1 To NumArrayCols) As Variant
Set ThisAtt = Wells.CurrWell.FirstAttribute(Skip:=False)
k = 1
OutArray(1, k) = "UWI"
Do
    ElevOffset = 0
    Set ThisAtt = Wells.CurrWell.CurrAttribute
    If InStr(LCase(ThisAtt.Name1), "elevation") Then
        OutArray(1, k + 1) = ThisAtt.Name1
        OutArray(1, k + 2) = ""
        OutArray(1, k + 3) = ThisAtt.Name2
        OutArray(1, k + 4) = ""
        ElevOffset = ElevOffset + 2
    Else
        OutArray(1, k + 1) = ThisAtt.Name1
        OutArray(1, k + 2) = ThisAtt.Name2
    End If
    OutArray(1, k + ElevOffset + 3) = "Recommend"
    OutArray(1, k + ElevOffset + 4) = "Rec. Value"
    OutArray(1, k + ElevOffset + 5) = "Comments"
    k = k + ElevOffset + 2 + AdditionalColumns
Loop While Not (Wells.CurrWell.NextAttribute(EnableSkipping:=False) Is Nothing)

Dim Destination As Range
Set Destination = NewSheet.Range("A1")
Destination.Resize(UBound(OutArray, 1), UBound(OutArray, 2)).Value = OutArray

这很奇怪，因为 OutArray 中的每个元素，经过检查，似乎都在那里。我的手动生成的数组工作正常，但自动生成的数组——在几乎所有方面看起来都相似——不起作用。有谁知道为什么？

4

1 回答 1

5

我怀疑这只是你的REDIM陈述。在你的第一个例子中，你有这个：

ReDim OutArray(1 To 1, 1 To NumArrayCols) As Variant

但在第二个例子中你这样做：

ReDim OutArray(1, 1 To NumArrayCols) As Variant

注意到区别了吗？当您说ReDim A(1 To 1)上限和下限均为 1，但Redim(1)仅说上限为 1 时，下限设置为默认值，即零 (0)。因此，这两个数组的形状/大小不同，因此在第二种情况下，您的数组不适合目标范围。

于 2013-01-30T19:08:21.207 回答