1

我有 flex mxml 自定义组件（图形）。根据要求需要将它们复制为复制或剪切操作。但是 registerClassAlias() 方法中的问题，它将如何用于自定义图形或 Group（或 UIComponents）组件。

var className:String = getQualifiedClassName(zorder.getItemAt(0));
            _saveIn.clear();

            registerClassAlias(className, zorder.getItemAt(0) as Class);
            _saveIn   =     SharedObject.getLocal("save");
            _saveIn.data.value1 = new ByteArray();
            _saveIn.data.value1.writeObject(zorder.getItemAt(0));
            _saveIn.data.value1.position = 0;
            _saveIn.flush();
4

2 回答 2

2

不可能通过 ByteArray 使用registerClassAlias->writeObject->readObject方法制作任何显示对象的完整副本。它仅适用于简单对象，例如数据对象（如 TextFormat、值对象等）。在任何情况下，您都必须为每种类型的对象测试复制方法，以确保它正常工作。

应对示例Shape，最简单的展示对象：

package
{
import avmplus.getQualifiedClassName;

import flash.display.DisplayObject;
import flash.display.MovieClip;
import flash.display.Shape;
import flash.net.registerClassAlias;
import flash.utils.ByteArray;
import flash.utils.getDefinitionByName;


public class astest extends MovieClip
{
    public function astest()
    {
        init();
    }

    private function init():void
    {
        var sh:Shape = new Shape();

        sh.graphics.beginFill(0xFF0000);
        sh.graphics.drawEllipse(100, 100, 100, 70);
        sh.graphics.endFill();

        addChild(sh);

        registerObject(sh);

        var ba:ByteArray = new ByteArray();
        ba.writeObject(sh);
        ba.position = 0;
        var obj:Object = ba.readObject();
        var shCopy:DisplayObject = obj as DisplayObject;

        if(shCopy)
        {
            shCopy.x = shCopy.y = 100;
            addChild(shCopy);
        }

    }

    private function registerObject(obj:Object):void
    {
        try
        {
            var qname:String = getQualifiedClassName(obj);
            var cname:String = qname.split("::").join(".");
            var classs:Class = getDefinitionByName(cname) as Class;
            registerClassAlias(qname, classs);
        }catch(error:Error)
        {
            trace(error.message);
        }
    }
}
}

输出：

   TypeError: Error #1034: Type Coercion failed: cannot convert Object@eae09b9 to flash.geom.Transform.

因此，您可以尝试flash.geom.Transform在应对之前注册：

registerObject(sh.transform);

但这会导致另一个错误：

ArgumentError: Error #1063: Argument count mismatch on flash.geom::Transform(). Expected 1, got 0

实际上，DisplayObject应对是老话题，您可以通过我上面提到的错误（尤其是最后一个）在谷歌上搜索很多关于此的帖子，但答案是：您无法通过 ByteArray 复制显示对象，您需要编写自定义用于创建给定 TextField、Sprite 或 VBox 的副本并手动复制所有属性的方法。

于 2013-01-29T09:14:34.767 回答
0

好的，这篇博文有一个简单的解决方案......你使用getDefinitionByName()：

所以在你的代码中是这样的：

var className:String = getQualifiedClassName(zorder.getItemAt(0));
            _saveIn.clear();

            registerClassAlias(className, getDefinitionByName(className) as Class);
            _saveIn   =     SharedObject.getLocal("save");
            _saveIn.data.value1 = new ByteArray();
            _saveIn.data.value1.writeObject(zorder.getItemAt(0));
            _saveIn.data.value1.position = 0;
            _saveIn.flush();
于 2013-01-29T08:43:41.743 回答