4

我正在使用 CMake 来定义我的项目。我的目标是让特定于平台的文件易于访问，以便在所有平台上进行编辑、搜索、浏览和源代码控制。

我目前在 cmake 描述中分离了特定于平台的文件。我的 CMakeLists.txt 文件如下所示：

 Foo.hpp
 ${platform_directory}/Foo.cpp

然后在磁盘上我有这样的东西：

 Foo.hpp
 win
  `- Foo.cpp 
 osx
  `- Foo.cpp

在生成的项目文件中如下所示：

 Foo.hpp
 Foo.cpp (platform-specific version)

这对于编译器来说是完美的，但这意味着开发人员缺乏用于非本地平台特定文件的 IDE 工具。

我正在寻找的是这样的（在 Xcode 中）：

 Foo.hpp
 Foo.cpp (OS X version)
 win
  `- Foo.cpp (file type set to plain text)

或在 Visual Studio 中：

 Foo.hpp
 Foo.cpp (Windows version)
 osx
  `- Foo.cpp (build action set to none)

关于如何设置 CMake 的任何想法？

4

2 回答 2

5

一种方法是添加一个没有构建规则的自定义目标，特别是保存不属于给定平台构建的文件；例如

if(WIN32)
  add_library(Foo Foo.hpp win/Foo.cpp)
  add_custom_target(NonWindows SOURCES osx/Foo.cpp)
  source_group("osx" osx/Foo.cpp)
else(APPLE)
  add_library(Foo Foo.hpp osx/Foo.cpp)
  add_custom_target(NonApple SOURCES win/Foo.cpp)
  source_group("win" win/Foo.cpp)
endif()

另一种选择（可能更接近您想要的，但更“hacky”）是将所有文件添加到目标，但将构建不需要的文件标记为HEADER_FILE_ONLY：

add_library(Foo Foo.hpp win/Foo.cpp osx/Foo.cpp)
if(WIN32)
  set_source_files_properties(osx/Foo.cpp PROPERTIES HEADER_FILE_ONLY TRUE)
  source_group("osx" osx/Foo.cpp)
else(APPLE)
  set_source_files_properties(win/Foo.cpp PROPERTIES HEADER_FILE_ONLY TRUE)
  source_group("win" win/Foo.cpp)
endif()
于 2013-02-05T08:28:17.467 回答
3

Fraser建议的 HEADER_FILE_ONLY技术效果很好，但是显式配置应该在哪个平台上编译哪些文件变得乏味。

给定一个 CMake 函数，如下所示：

function (DisableCompilingPlatformSpecificSources file_list)
   foreach(file ${file_list})
      if (
         ((${file} MATCHES "^(.*)Win32\\.cpp") AND NOT WIN32) OR
         ((${file} MATCHES "^(.*)Unix\\.cpp")  AND NOT UNIX)  OR
         ((${file} MATCHES "^(.*)Apple\\.cpp") AND NOT APPLE)
      )
         set_source_files_properties(
            ${file}
            PROPERTIES HEADER_FILE_ONLY TRUE
         )
      endif()
   endforeach()
endfunction()

我们可以通过它们的后缀来控制特定于平台的源。例如：

set(all_sources
   Foo.hpp
   FooWin32.cpp # windows-specific
   FooApple.cpp # apple-specific
)

DisableCompilingPlatformSpecificSources("${all_sources}")

add_executable(foo ${all_sources})

这与gyp处理特定平台文件的方式非常相似，并且可以根据需要轻松扩展以支持其他后缀。

于 2014-05-05T05:02:56.980 回答