3

我有一些XML如下；

<risk>
  <driver driverId="2">
    <vehicleUse>M</vehicleUse>
  </driver>
  <driver driverId="3">
    <vehicleUse>F</vehicleUse>
  </driver>
  <driver driverId="4">
    <vehicleUse>I</vehicleUse>
  </driver>
</risk>

我正在使用 XSLT（v1.0，.NET 实现）将每个 vehicleUse 转换为一个数字，然后得到这些数字的总和。车辆使用被翻译为 M=3、F=2 和 I=1。一个额外的复杂性是，对于 ID 为 3 的驱动程序，这些值乘以 10，而对于驱动程序 4，则乘以 100。因此，在上面的示例中，总数为 3 + 20 + 100 = 123。

我已经像这样在我的 XSLT 文件中定义了一个模板；

<xsl:template name="getVehicleUseScore">
  <xsl:param name="driverId" />
  <xsl:param name="vehicleUse" />
  <!-- Implementation left out for brevity -->
</xsl:template>

然后 XSLT 文件的其余部分调用模板；

<xsl:template match="risk">
  <vehicleUseScore>
    <xsl:for-each select="driver">
      <xsl:call-template name="getVehicleUseScore">
        <xsl:with-param name="driverId" select="@driverId" />
        <xsl:with-param name="vehicleUse" select="vehicleUse" />
      </xsl:call-template>
    </xsl:for-each>
  </vehicleUseScore>
</xsl:template>

<xsl:template match="/">
  <xsl:apply-templates />
</xsl:template>

结果是我得到了文本“320100”，它只是将 3、20 和 100 连接在一起，这至少证明了 getVehicleUseScore 模板有效。

我想将 getVehicleUseScore 的结果传递给 sum() 函数，但我不知道如何。我尝试了以下方法；

<xsl:value-of select="sum(getVehicleUseScore(@driverId, vehicleUse))" />

但是 XSLT 编译器声明“getVehicleUseScore() 是一个未知的 XSLT 函数”。

有没有办法做到这一点？

4

2 回答 2

1

这是执行此操作的简短 XSLT 1.0 方法：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

 <xsl:template match="risk">
  <vehicleUseScore>
   <xsl:variable name="vrtfResult">
        <xsl:for-each select="driver">
          <xsl:call-template name="getVehicleUseScore">
            <xsl:with-param name="pdriverId" select="@driverId" />
            <xsl:with-param name="pvehicleUse" select="vehicleUse" />
          </xsl:call-template>
        </xsl:for-each>
    </xsl:variable>

    <xsl:value-of select="sum(msxsl:node-set($vrtfResult)/*)"/>
  </vehicleUseScore>
 </xsl:template>

 <xsl:template name="getVehicleUseScore">
  <xsl:param name="pdriverId" />
  <xsl:param name="pvehicleUse" />
  <score>
   <xsl:variable name="vValue" select=
   "(($pvehicleUse='M')*3 + ($pvehicleUse='F')*2 + ($pvehicleUse='I')*1)"/>
   <xsl:variable name="vFactor" select=
   "1 +(9*($pdriverId=3)) + (99*($pdriverId=4))"/>

   <xsl:value-of select="$vValue*$vFactor"/>
  </score>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<risk>
    <driver driverId="2">
        <vehicleUse>M</vehicleUse>
    </driver>
    <driver driverId="3">
        <vehicleUse>F</vehicleUse>
    </driver>
    <driver driverId="4">
        <vehicleUse>I</vehicleUse>
    </driver>
</risk>

产生了想要的正确结果：

<vehicleUseScore>123</vehicleUseScore>

说明：

在变量中捕获模板的输出时，此变量的类型为 RTF（结果树片段），除非其内容包含任何节点（文本节点除外），否则 XPath 表达式无法导航其内容。

为此，xxx:node-set()需要对该变量调用依赖于供应商的扩展函数，以便将 RTF 转换为常规树。

在这里，我们还使用了这样一个事实，即每当在算术表达式中遇到布尔值时，它都会被转换为数字，并且根据定义：

number(true()) = 1

和

number(false()) = 0
于 2013-01-25T22:18:19.320 回答
1

另一种更冗长但避免使用node-set()函数的方法（我喜欢尽可能避免使用专有函数，即使node-set()只是半专有的）是使用递归：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="risk">
    <vehicleUseScore>
      <xsl:call-template name="sumDriverScores">
        <xsl:with-param name="drivers" select="driver" />
      </xsl:call-template>
    </vehicleUseScore>
  </xsl:template>

  <xsl:template name="sumDriverScores">
    <xsl:param name="drivers" />

    <xsl:if test="not($drivers)">
      <xsl:text>0</xsl:text>
    </xsl:if>
    <xsl:if test="$drivers">
      <xsl:variable name="currentValue">
        <xsl:call-template name="getVehicleUseScore">
          <xsl:with-param name="driverId" select="$drivers[1]/@driverId" />
          <xsl:with-param name="vehicleUse" select="$drivers[1]/vehicleUse" />
        </xsl:call-template>
      </xsl:variable>

      <xsl:variable name="sumRemainder">
        <xsl:call-template name="sumDriverScores">
          <xsl:with-param name="drivers" select="$drivers[position() > 1]" />
        </xsl:call-template>
      </xsl:variable>

      <xsl:value-of select="$currentValue + $sumRemainder"/>
    </xsl:if>
  </xsl:template>


  <xsl:template name="getVehicleUseScore">
    <xsl:param name="driverId" />
    <xsl:param name="vehicleUse" />
    <xsl:variable name="useFactor" select="translate($vehicleUse, 'MFI', '321')"/>
    <xsl:variable name="idFactor" 
                  select="1 + 9 * ($driverId = 3) +  99 * ($driverId = 4)"/>

    <xsl:value-of select="$useFactor * $idFactor"/>
  </xsl:template>
</xsl:stylesheet>

输出是：

<vehicleUseScore>123</vehicleUseScore>
于 2013-01-26T15:30:13.090 回答