1

我在 F# 中做了一个函数

let tryParseArray tryParse (separator:char) (line: string) =
    // inside the function I use the tuple form of tryParse

如果我以这种方式调用它，它工作正常：tryParseArray Int32.TryParse ',' "2,3,2,3,2"

现在我希望这个函数也可以在 C# 中使用，所以我这样做了：

static member TryParseArray (line, tryParse, separator) =
    line |> tryParseArray tryParse separator

然后我意识到TryParseArray实际上需要tryParse参数 as FSharpFunc，这对 C# 一点也不友好，所以我尝试了这个：

static member TryParseArray (line, [<Out>] tryParse: (string * byref<'a> -> bool), separator) =
    line |> tryParseArray tryParse separator

但现在tryParseArray不接受tryParse作为有效参数（类型错误）

我应该怎么办？

我希望在 C# 中我也可以TryParseArray("2,3,2,3,2", Int32.TryParse, ',')调用

4

2 回答 2

5

您可以使用自定义委托类型将此函数公开给 C#：

已编辑

// F#
module Lib

let tryParseArray parser (line : string) (sep : char) = 
    // don't know your exact implementation so again just guessing...
    line.Split sep
    |> Array.choose (fun el ->
        match parser el with
        | true, el -> Some el
        | false, _ -> None
        )

open System.Runtime.InteropServices
type TryParse<'R>  = delegate of str : string * [<Out>] res : byref<'R> -> bool

type T = 
    static member TryParse(line : string, tryParse : TryParse<'R>, separator : char) : 'R[] = 
        tryParseArray tryParse.Invoke line separator


 //C# 
 var r = Lib.T.TryParse<int>("1,2,3", int.TryParse, ',');

注意：在 C# 方面，您需要明确指定 TryParse 的类型参数（为什么匿名委托/lambdas 不推断 out/ref 参数的类型？）

于 2013-01-25T01:37:37.673 回答
0

desco 的解决方案很好，但如果你想避免byref，你可以这样做：

type TryParse<'R>  = delegate of string -> bool * 'R

module Util =
  [<CompiledName("TryParseArray")>]
  let tryParseArray (tryParse: TryParse<_>) (separator:char) (line: string) = ...

可以像这样从 F# 调用：

let res = Util.tryParseArray (TryParse(Int32.TryParse)) ',' "1,2,3"

并且，使用以下包装方法：

static class TryParse {
    public static Tuple<bool, int> Int32(string s) {
        int i;
        var b = System.Int32.TryParse(s, out i);
        return Tuple.Create(b, i);
    }
}

像这样，来自 C#：

var res = Util.TryParseArray(TryParse.Int32, ',', "1,2,3");
于 2013-01-25T16:15:04.843 回答