4

我正在尝试实现一个可以进行浮点运算的 flex/bison 计算器。我的弹性代码看起来像这样

%{
#include "calc.tab.h"
#include <stdlib.h>

void yyerror(char *s);
%}

digit [0-9]
integer {digit}+
real ({digit}+[.]{digit}*)|({digit}*[.]{digit}+)
exp ({integer}|{real})[eE]-?{integer}

%%

({integer}|{real}|{exp}) { yylval = atof(yytext); return NUMBER; }
[-+*/\n]                 { return *yytext; }
[ \t\v\f\r]              { }
.                        { yyerror("Unknown Character"); }

%%

int yywrap(void)
{
  return 1;
}

我的野牛代码看起来像这样

%{
#include <stdio.h>

typedef double YYSTYPE;
#define YYSTYPE_IS_DECLARED

void yyerror(char *s);
extern char *yytext;
extern int yylineno;
%} 

%token NUMBER

%left '+' '-'
%left '*' '/'

%%

program: program expr '\n' { printf("%g\n", $2); }
       | program '\n'
       |
       ;
expr: expr '+' expr { $$ = $1 + $3; }
    | expr '-' expr { $$ = $1 - $3; }
    | expr '*' expr { $$ = $1 * $3; }
    | expr '/' expr { $$ = $1 / $3; }
    | NUMBER { $$ = $1; }
    ;

%%

void yyerror(char *s)
{
  fprintf(stderr, "error: %s at %s, line %d\n", s, yytext, yylineno);
}

int main(int argc, char *argv[])
{
  yyparse();

  return 0;
}

这不会产生正确的输出。尽管词法分析器将字符串解释为双精度并将它们正确存储在yylval变量中，但当解析器将数字相加时，它只会吐出0.0000. 但是，如果我通过仅由一个变量组成的指令声明yylval为联合，并将输出存储在词法分析器的该字段中，并在解析器中声明和，那么一切似乎都有效。%uniondouble lf_val;atofyylval%token <lf_val> NUMBER%type <lf_val> expr

但是，为什么直接的typedefing方法YYSTYPE不起作用呢？我也试过了#define YYSTYPE double。那也没有用。

4

1 回答 1

5

关于%code，Bison 的文档指出：

%code requires [...] is the best place to override Bison's default YYSTYPE
and YYLTYPE definitions.

所以只需在你的野牛文件顶部添加以下内容：

%code requires
  {
    #define YYSTYPE double
  }

您还需要删除这两行：

typedef double YYSTYPE;
#define YYSTYPE_IS_DECLARED

请注意，据我所知，YYSTYPE_IS_DECLARED 没有记录在任何地方，因此仅供 Bison 内部使用。

如果您不熟悉 Bison%code指令在简单%{序言中的使用，您可能会发现文档的这一部分很有趣。

于 2013-01-22T17:36:06.297 回答