9

是否可以在运行时生成和运行 TemplateHaskell 生成的代码？

在运行时使用 C，我可以：

  • 创建函数的源代码，
  • 调用 gcc 将其编译为 .so (linux)（或使用 llvm 等），
  • 加载 .so 和
  • 调用函数。

模板 Haskell 是否可以做类似的事情？

4

2 回答 2

13

是的，这是可能的。GHC API 将编译 Template Haskell。https://github.com/JohnLato/meta-th提供了一个概念验证，虽然不是很复杂，但它展示了一种通用技术，它甚至提供了一点类型安全性。模板 Haskell 表达式是使用该Meta类型构建的，然后可以编译并加载到可用函数中。

{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TemplateHaskell #-}

{-# OPTIONS_GHC -Wall #-}
module Data.Meta.Meta (
-- * Meta type
  Meta (..)

-- * Functions
, metaCompile
) where

import Language.Haskell.TH

import Data.Typeable as Typ
import Control.Exception (bracket)

import System.Plugins -- from plugins
import System.IO
import System.Directory

newtype Meta a = Meta { unMeta :: ExpQ }

-- | Super-dodgy for the moment, the Meta type should register the
-- imports it needs.
metaCompile :: forall a. Typeable a => Meta a -> IO (Either String a)
metaCompile (Meta expr) = do
  expr' <- runQ expr

  -- pretty-print the TH expression as source code to be compiled at
  -- run-time
  let interpStr = pprint expr'
      typeTypeRep = Typ.typeOf (undefined :: a)

  let opener = do
        (tfile, h) <- openTempFile "." "fooTmpFile.hs"
        hPutStr h (unlines
              [ "module TempMod where"
              , "import Prelude"
              , "import Language.Haskell.TH"
              , "import GHC.Num"
              , "import GHC.Base"
              , ""
              , "myFunc :: " ++ show typeTypeRep
              , "myFunc = " ++ interpStr] )
        hFlush h
        hClose h
        return tfile
  bracket opener removeFile $ \tfile -> do

      res <- make tfile ["-O2", "-ddump-simpl"]
      let ofile = case res of
                    MakeSuccess _ fp -> fp
                    MakeFailure errs -> error $ show errs
      print $ "loading from: " ++ show ofile
      r2 <- load (ofile) [] [] "myFunc"
      print "loaded"

      case r2 of
        LoadFailure er -> return (Left (show er))
        LoadSuccess _ (fn :: a) -> return $ Right fn

这个函数需要一个ExpQ, 并且首先在 IO 中运行它来创建一个普通的Exp. 然后将Exp其漂亮地打印到源代码中，在运行时编译和加载。在实践中，我发现更困难的障碍之一是在生成的 TH 代码中指定正确的导入。

于 2013-01-22T13:49:47.867 回答
5

据我了解，您想在运行时创建和运行代码，我认为您可以使用GHC API来完成，但我不太确定您可以实现的范围。如果您想要诸如热代码交换之类的东西，可以查看包hotswap。

于 2013-01-22T13:26:47.380 回答