emacs - 如何突出显示emacs中的特定行？

Question

我需要突出显示 emacs 的功能，以便在使用它时标记文件中的某些行。它应该有点像M-s h l，但应该基于行号，而不是正则表达式。我想突出显示当前行，但hl-line-mode不适合，因为我需要突出显示许多行，每次按每个特定键时。

Answer 1

我只是快速写了以下内容：

(defun find-overlays-specifying (prop pos)
  (let ((overlays (overlays-at pos))
        found)
    (while overlays
      (let ((overlay (car overlays)))
        (if (overlay-get overlay prop)
            (setq found (cons overlay found))))
      (setq overlays (cdr overlays)))
    found))

(defun highlight-or-dehighlight-line ()
  (interactive)
  (if (find-overlays-specifying
       'line-highlight-overlay-marker
       (line-beginning-position))
      (remove-overlays (line-beginning-position) (+ 1 (line-end-position)))
    (let ((overlay-highlight (make-overlay
                              (line-beginning-position)
                              (+ 1 (line-end-position)))))
        (overlay-put overlay-highlight 'face '(:background "lightgreen"))
        (overlay-put overlay-highlight 'line-highlight-overlay-marker t))))


(global-set-key [f8] 'highlight-or-dehighlight-line)

（这里的 find-overlays-specifying 来自手册页）

它将突出显示当前行，再次使用时会将其删除。

也许以下内容也可能有用：从缓冲区中删除所有突出显示（可能很危险，如果您突出显示重要的事情，您可能不想要它）

(defun remove-all-highlight ()
  (interactive)
  (remove-overlays (point-min) (point-max))
  )

(global-set-key [f9] 'remove-all-highlight)

Answer 2

您可以使用bm.el。您可以从 MELPA 安装 bm.el。

bm.el 提供bm-toggle突出显示和取消突出显示当前行。bm.el 还提供了bm-bookmark-regexp仅突出显示匹配的行。bm-previous您可以通过and在突出显示的行之间跳转bm-next

以下是 bm.el 的示例配置

(require 'bm)
(global-set-key (kbd "<f5>") 'bm-toggle)
(global-set-key (kbd "<f6>") 'bm-previous)
(global-set-key (kbd "<f7>") 'bm-next)
(global-set-key (kbd "<f8>") 'bm-bookmark-regexp)

Answer 3

Bookmark+可以满足您的要求。使用C-x p RET（默认情况下）在点设置书签。您可以为此类书签配置所需的突出显示类型。这类似于bm.el提供的（syohex 的答案），但更灵活。