2

我需要通过添加一个 CSS 类来用红色突出显示字符串（HTML 标题）中的前两个单词，这tokenize就是我现在正在查看的内容。这到底是怎么做到的？如果可能的话。

一些伪代码：

<xsl:for-each select="tokenize(title, '\s+')">
    // ......
    <xsl:attribute name="class">
        <xsl:text>className</xsl:text>
    </xsl:attribute>

</xsl:for-each>

我如何挑选结果中的每个单词？

虽然，tokenize 可能不是解决方案。任何帮助表示赞赏！

4

3 回答 3

1

可以在这里使用tokenize，特别是如果您想处理除单个空格之外的其他单词分隔符（tokenize的第二个参数允许指定正则表达式。

无论如何，在您的情况下，可能值得将 tokenize 的结果分配给一个变量，然后对前两个单词采取不同的操作。尝试以下 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:template match="/*">
      <h1>
         <xsl:variable name="words" select="tokenize(title, ' ')"/>
         <span class="className">
            <xsl:value-of select="concat($words[1], ' ', $words[2])"/>
         </span>
         <xsl:for-each select="$words[position() &gt; 2]">
            <xsl:value-of select="concat(' ', .)"/>
         </xsl:for-each>
      </h1>
   </xsl:template>
</xsl:stylesheet>

以这个 XML 为例

<data>
   <title>This is a test</title>
</data>

以下是输出

<h1>
   <span class="className">This is</span> a test
</h1>
于 2013-01-21T09:05:36.787 回答
1

使用 tokenize() 的缺点是会丢失标记之间的分隔符。这里更好的解决方案是 xsl:analyze-string：

<xsl:analyze-string select="title" regex="\s+ (or whatever)">
  <xsl:matching-substring><xsl:value-of select="."/></xsl:matching-substring>
  <xsl:non-matching-substring>
    <xsl:choose>
      <xsl:when test="position() le 4">
         <span class="xxxx"><xsl:value-of select="."/></span>
      </xsl:when>
      <xsl:otherwise><xsl:value-of select="."/></xsl:otherwise>
   </xsl:choose>
 </xsl:non-matching-substring>
</xsl:analyze-string>

如果您使用允许单词之间标点符号的正则表达式，则可以确保标点符号不会丢失。您还可以反转测试并使用匹配单词而不是单词间分隔符的正则表达式。

position() le 4 测试允许序列可能以单词或单词间分隔符开头。

于 2013-01-21T15:16:38.840 回答
1

你很亲密。这是一个完整的转换：

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <h1>
    <xsl:variable name="vWords" select="tokenize(., '\s+')"/>
    <span class="className">
      <xsl:value-of select="$vWords[not(position() gt 2)]" separator=" "/>
      <xsl:text> </xsl:text>
    </span>
      <xsl:value-of select="$vWords[position() gt 2]" separator=" "/>
  </h1>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于此 XML 文档时：

<t>Red cat and a mouse</t>

产生了想要的正确结果：

<h1><span class="className">Red cat </span>and a mouse</h1>
于 2013-01-21T13:16:26.970 回答