1

我知道图像将在 AS3 中异步加载，并且应该使用事件和事件侦听器来处理同步。

因此，在一个简单的情况下，它看起来像这样：

var loader : Loader = new Loader();
var im_file: URLRequest = new URLRequest ("imfile.png");
loader.load(im_file);
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loading_complete);

function loading_complete (e : Event) : void
{ // ... do smt with your loaded data // }

我想要做的是有一个 PreLoader 类，它将预先加载我需要的所有图像。在这种情况下，我如何让所有其他类知道加载何时完成？

我要发送事件吗？在这种情况下，最佳做法是什么？

提前致谢，

普拉斯卡顿

4

2 回答 2

1

您很可能想要创建一个队列并将您的图像路径添加到队列中。然后在每个图像完成加载后，您继续到队列中的下一个项目。当所有图像都加载完毕后，你会发送一个 COMPLETE 事件或类似的东西来让你的应用知道它已经完成了。

检查QueueLoader或Casalib以了解它们如何实现单个或批量图像加载。

于 2013-01-20T20:50:11.263 回答
0

除了@Boon 提供的答案之外，这就是您实际设置图像队列的方式。

首先，您需要一个列表来存储所有仍需要加载的图像。这使您可以轻松定义任意数量的图像。它可以是“队列”：

var queue:Array = [
    "http://interfacelift.com/wallpaper/previews/03177_orionnebulaintheinfrared@2x.jpg",
    "http://interfacelift.com/wallpaper/previews/03175_purpleclouds@2x.jpg",
    "http://interfacelift.com/wallpaper/previews/03173_goodmorning2013@2x.jpg"
];

接下来要做的是设置我所说的我们正在做的“核心”方法。它将处理加载下一个图像以及在队列为空时通知我们。它看起来像这样：

function loadNext():void
{
    if(queue.length > 0)
    {
        // Notice here that we use .pop() on the queue, which will select and
        // remove the last item from queue.
        var req:URLRequest = new URLRequest( queue.pop() );
        var photo:Loader = new Loader();

        photo.load(req);
        photo.contentLoaderInfo.addEventListener(Event.COMPLETE, loadComplete);
    }
    else
    {
        // The queue is finished - dispatch an event or whatever you fancy to
        // let the rest of the application know we're done here.
        trace("Queue finished.");
    }
}

然后当然是我们的监听函数来处理加载图像的完成。请注意，我们在这里调用loadNext()- 这是仅在当前加载图像完成后才开始加载队列中下一个图像的关键。

function loadComplete(e:Event):void
{
    addChild(e.target.content as Bitmap);


    // Begin loading next image in the queue.
    loadNext();
}

为了开始这个过程，我们当然只是使用它，如果队列为空，它将立即通知我们队列已完成，或者开始按顺序加载图像。

// Start loading the queue.
loadNext();

补充/整理：

如果您希望能够回收此代码或只是整理一下，您可以轻松地将其制作成一个类。可以调用该类ImageQueue，其结构将包含上述queue数组、loadNext()方法和loadComplete()方法。它还可以有一种add()方法，以一种更简洁的方式将图像最初添加到队列中。

这是该课程的基础，如果您有兴趣，可以完成：

public class ImageQueue
{

    private var _queue:Array = [];

    public function add(image:String):void{ }
    public function loadNext():void{ }

    private function _loadComplete(e:Event):void{ }

}
于 2013-01-20T22:50:42.853 回答