c# - 如果它是结构数组，foreach 是否会复制每个元素？

Question

我有一个结构数组。foreach遍历数组时，运算符是否会复制每个元素？据我了解foreach，只是将引擎盖下的语法糖转换为for. 所以看起来答案是否定的，但我很想得到一些确认。

PS：似乎有人应该已经问过了，但我找不到任何东西。因此，请在提供参考的情况下以 dup 的身份投票。

Answer 1

是的，将制作值类型实例的副本。当迭代一个数组时，foreach确实会使用数组访问而不是使用枚举器，但是每个数组槽中的值仍然被复制。

这段代码：

struct AStruct
{
    public string a;
    public int b;

    static void Main()
    {
        var structs = new AStruct[10];

        foreach (var x in structs) {
            Console.WriteLine(x);
        }
    }
}

为该Main()方法生成以下 IL：

.method private static hidebysig
       default void Main ()  cil managed
{
    .entrypoint
    .maxstack 4
    .locals init (
            valuetype AStruct[]     V_0,
            valuetype AStruct[]     V_1,
            int32   V_2,
            valuetype AStruct       V_3)
    IL_0000:  ldc.i4.s 0x0a
    IL_0002:  newarr AStruct
    IL_0007:  stloc.0
    IL_0008:  ldloc.0
    IL_0009:  stloc.1
    IL_000a:  ldc.i4.0
    IL_000b:  stloc.2
    IL_000c:  br IL_002d

    IL_0011:  ldloc.1
    IL_0012:  ldloc.2
    IL_0013:  ldelema AStruct
    IL_0018:  ldobj AStruct
    IL_001d:  stloc.3
    IL_001e:  ldloc.3
    IL_001f:  box AStruct
    IL_0024:  call void class [mscorlib]System.Console::WriteLine(object)
    IL_0029:  ldloc.2
    IL_002a:  ldc.i4.1
    IL_002b:  add
    IL_002c:  stloc.2
    IL_002d:  ldloc.2
    IL_002e:  ldloc.1
    IL_002f:  ldlen
    IL_0030:  conv.i4
    IL_0031:  blt IL_0011

    IL_0036:  ret
} // end of method AStruct::Main

请注意指令 IL_0013 到 IL_001d。每个数组槽的整个值都被压入堆栈并存储在本地 V_3（x迭代变量）中。