92

我有一个 Google 电子表格，其中有一列如下所示：

City
----
London
Paris
London
Berlin
Rome
Paris

我想计算每个不同城市的出现次数（所以我需要城市名称和出现次数）。

City   | Count
-------+------
London |  2
Paris  |  2
Berlin |  1
Rome   |  1

我怎么做？

4

7 回答 7

113

链接到工作示例

解决方案 0

这可以使用数据透视表来完成。

数据透视表示例 - 按值计算行数

解决方案 1

使用unique公式获取所有不同的值。然后用于countif获取每个值的计数。请参阅顶部的工作示例链接，以了解其具体实现方式。

Unique Values        Count
=UNIQUE(A3:A8)       =COUNTIF(A3:A8;B3)
                     =COUNTIF(A3:A8;B4)
                     ...

解决方案 2

如果您这样设置数据：

City    
----    
London   1
Paris    1
London   1
Berlin   1
Rome     1
Paris    1

然后以下将产生所需的结果。

=sort(transpose(query(A3:B8,"Select sum(B) pivot (A)")),2,FALSE)

我确信有一种方法可以摆脱第二列，因为所有值都是 1。我认为这不是一个理想的解决方案。

通过http://googledocsforlife.blogspot.com/2011/12/counting-unique-values-of-data-set.html

其他可能有用的链接

于 2013-01-25T14:09:00.467 回答
27

您可以使用该query函数，因此如果您的数据位于第一行是列标题的 col A 中...

=query(A2:A,"select A, count(A) where A != '' group by A order by count(A) desc label A 'City'", 0)

产量

City    count 
London  2
Paris   2
Berlin  1
Rome    1

链接到有效的 Google 表格。

https://docs.google.com/spreadsheets/d/1N5xw8-YP2GEPYOaRkX8iRA6DoeRXI86OkfuYxwXUCbc/edit#gid=0

于 2017-06-06T23:47:45.270 回答
21

=iferror(counta(unique(A1:A100)))计算从 A1 到 A100 的唯一单元格的数量

于 2013-09-01T20:03:08.090 回答
11

不完全是用户的要求，而是一种计算唯一值的简单方法：

Google 推出了一项新功能，只需一步即可计算唯一值，您可以将其用作其他公式的输入：

=COUNTUNIQUE(A1:B10)

于 2016-06-25T09:56:33.550 回答
7

如果您只想计算以下范围内的唯一值的计数，则此方法有效

=counta(unique(B4:B21))
于 2019-04-10T03:35:23.553 回答
0

这类似于@JSuar 的解决方案 1 ...

假设您的原始城市数据是一个名为的命名范围dataCity。在新工作表中，输入以下内容：

    A                 | B
  ----------------------------------------------------------
1 | =UNIQUE(dataCity) | Count
2 |                   | =DCOUNTA(dataCity,"City",{"City";$A2})
3 |                   | [copy down the formula above]
4 |                   | ...
5 |                   | ...
于 2014-10-13T19:33:36.043 回答
-5

=UNIQUE({filter(Core!L8:L27,isblank(Core!L8:L27)=false),query(ArrayFormula(countif(Core!L8:L27,Core!L8:L27)),"选择 Col1 其中 Col1 < > 0")})

核心！L8:L27 = 列表

于 2018-11-15T08:10:01.153 回答