0

使用以下 XML：

<Sections><Section Type="Type1" Text="blabla1"><Section Type="Type2" Text="blabla2"/>  </Section></Sections>

我想产生以下输出：

<Sections><Type1 Text="blabla1"><Type2 Text="blabla2"/></Type1></Sections>

我玩 XSLT 已经好几个小时了，我什至想不出从什么开始……关于 XLST 转换有很多很好的例子，但我仍然缺少一些关于递归性和使用 Type 属性来创建我的节点的东西。如何将文档中的任何节节点转换为其对应的类型属性？

任何做类似事情的教程、xslt 资源或任何开始的东西都很棒

谢谢

4

1 回答 1

3

这是怎么回事（根据评论中的要求，修改为双向转换）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- Prevent Type attributes from being copied to the output-->
  <xsl:template match="@Type" />

  <!-- Convert <Section Type="Nnn" ... /> into <Nnn ... /> -->
  <xsl:template match="Section">
    <xsl:element name="{@Type}">
      <xsl:apply-templates select="@* | node()"/>
    </xsl:element>
  </xsl:template>

  <!-- Convert <Nnn .... /> into <Section Type="Nnn" ... /> -->
  <xsl:template match="Sections//*[not(self::Section)]">
    <Section Type="{name()}">
      <xsl:apply-templates select="@* | node()" />
    </Section>
  </xsl:template>

</xsl:stylesheet>

在您的第一个示例上运行时的输出：

<Sections>
  <Type1 Text="blabla1">
    <Type2 Text="blabla2" />
  </Type1>
</Sections>

在第二个示例上运行时的输出：

<Sections>
  <Section Type="Type1" Text="blabla1">
    <Section Type="Type2" Text="blabla2" />
  </Section>
</Sections>
于 2013-01-16T06:03:05.043 回答