1

我有一个填充有文本文件的数据网格，其中包含逐行单词（即每行一个）。数据网格有 5 列。文本文件中的每 5 个单词被放入一个新行。然后可以添加或删除数据网格。我将如何使用数据网格中的所有值重写文本文件？

这就是填充数据网格的方式。如何遍历整个数据网格单元格并重写文本文件中的数据？

var loadFavourites: URLLoader = new URLLoader();;
var arFavourites = new Array();

loadFavourites.addEventListener(Event.COMPLETE, onLoadedFavourites);
loadFavourites.load(new URLRequest("lists/Favourites.txt"));

function onLoadedFavourites(event:Event):void
{
    arFavourites = event.target.data.split("\r\n");

    for (var i:int = 0; i <= arFavourites.length; i++)
    {
        if (i != 0 && i % 5 == 0)
        {
            dg.addItem({Place: arFavourites[i-5],Subject:arFavourites[i-4],Object:arFavourites[i-3],Feeling:arFavourites[i-2],Action:arFavourites[i-1]});

        }
    }
}

添加记录：

var i:int=0;
    var tPlace = mc_places.mc_places_text.txtPlaces.text;
    var tSubject = mc_subject.mc_subject_text.txtSubject.text;
    var tObject = mc_object.mc_object_text.txtObject.text;
    var tFeeling = mc_feeling.mc_feeling_text.txtFeeling.text;
    var tAction = mc_action.mc_action_text.txtAction.text;
    arFavourites[FavCount+1]=tPlace;
    arFavourites[FavCount+2]=tSubject;
    arFavourites[FavCount+3]=tObject;
    arFavourites[FavCount+4]=tFeeling;
    arFavourites[FavCount+5]=tAction;
    dg.addItem({Place: arFavourites[FavCount+1],Subject:arFavourites[FavCount+2],Object:arFavourites[FavCount+3],Feeling:arFavourites[FavCount+4],Action:arFavourites[FavCount+5]});
    dg.scrollToIndex(dg.length-1);
    FavCount=FavCount+5;
    for (i=0; i<arFavourites.length; i++) {
                trace(arFavourites[i]);
            }

删除记录：

var k:int;
    var i:int;
    trace("Selected Index: " + dg.selectedIndex);
    if (dg.length == 0) {
        return;
    }
    for (k=0; k<dg.length; k++) {
        if (dg.isItemSelected(dg.getItemAt(k))) {
            for (i=0; i<arFavourites.length; i++) {
                if (arFavourites[i] == dg.getItemAt(k)[1]) {
                    arFavourites.splice(i,1);
                    }
                if (arFavourites[i] == dg.getItemAt(k)[2]) {
                    arFavourites.splice(i,1);
                    }
                if (arFavourites[i] == dg.getItemAt(k)[3]) {
                    arFavourites.splice(i,1);
                    }
                if (arFavourites[i] == dg.getItemAt(k)[4]) {
                    arFavourites.splice(i,1);
                    }
                if (arFavourites[i] == dg.getItemAt(k)[5]) {
                    arFavourites.splice(i,1);
                    }
            }
            dg.removeItemAt(k);
            dg.scrollToIndex(k);
            dg.clearSelection();
            break;
        }
    }
4

1 回答 1

1

好吧，我会做的基本上是相反的。首先，您将获取 the 的值DataGrid并将它们Array按与以前相同的顺序放回：

var newFavArray:Array = new Array();

for (var i:int = 1; i <= dg.length; i++)
{
    newFavourites[i * 5 - 5] = dg.getItemAt(i - 1).Place;
    newFavourites[i * 5 - 4] = dg.getItemAt(i - 1).Subject;
    newFavourites[i * 5 - 3] = dg.getItemAt(i - 1).Object;
    newFavourites[i * 5 - 2] = dg.getItemAt(i - 1).Feeling;
    newFavourites[i * 5 - 1] = dg.getItemAt(i - 1).Action;
}

i（如果您能找到更好的使用方式来访问它Array并DataGrid随意使用它，我很快就完成了它。）

然后将其转换为String：

var newFavString:String = newFavArray.join("\r\n");

然后最后将它保存到您想要的文件中（当然覆盖旧值）。由于它是一个 AIR 应用程序，因此最好使用File和FileStream类：

var favFile:File = File.applicationStorageDirectory.resolvePath("lists/Favourites.txt");
var favStream:FileStream = new FileStream();

favStream.open(favFile, FileMode.WRITE);
favStream.writeUTFBytes(newFavString);
favStream.close();

我不确定您的工作流程是什么，但我个人会将所有这些都放在一个函数中：

function saveFavourites():void
{
    var newFavArray:Array = new Array();

    for (var i:int = 1; i <= dg.length; i++)
    {
        newFavArray[i * 5 - 5] = dg.getItemAt(i - 1).Place;
        newFavArray[i * 5 - 4] = dg.getItemAt(i - 1).Subject;
        newFavArray[i * 5 - 3] = dg.getItemAt(i - 1).Object;
        newFavArray[i * 5 - 2] = dg.getItemAt(i - 1).Feeling;
        newFavArray[i * 5 - 1] = dg.getItemAt(i - 1).Action;
    }

    var newFavString:String = newFavArray.join("\r\n");

    var favFile:File = File.applicationStorageDirectory.resolvePath("lists/Favourites.txt");
    var favStream:FileStream = new FileStream();

    favStream.open(favFile, FileMode.WRITE);
    favStream.writeUTFBytes(newFavString);
    favStream.close();
}

您可以随时运行。

如果您以前没有使用过File，FileStream那么值得一试，看看它们是如何工作的。它们仅在 AIR 中可用，但它们比 and 更好和优越URLRequest得多URLLoader。您可能还想使用它们来加载文件。但是，它们仅对本地文件有用，如果文件在线或其他什么，那么我确定没问题URLLoader。

于 2013-01-14T21:35:12.380 回答