14

我对 attoparsec 的这种行为有点困惑。

$ ghci
> :m Data.Attoparsec.Text
> :m + Data.Text
> parse (string (pack "module")) (pack "mox")
Partial _
> parse (string (pack "module")) (pack "moxxxx")
Fail "moxxxx" [] "Failed reading: takeWith"
>

为什么我需要添加字符来触发失败？

遇到第一个“x”不应该失败吗？

4

1 回答 1

13

这是一个实现细节，string解析器在知道是否还有足够的输入以使其可能成功之前不会完成。这是这些解析器全有或全无行为的结果（我认为，这通常对性能有好处）。

string :: Text -> Parser Text
string s = takeWith (T.length s) (==s)

string s尝试获取length s的单位Text，然后将它们与s.

takeWith :: Int -> (Text -> Bool) -> Parser Text
takeWith n p = do
  s <- ensure n
  let h = unsafeTake n s
      t = unsafeDrop n s
  if p h
    then put t >> return h
    else fail "takeWith"

takeWith n p首先尝试确保n单位Text可用，并且

ensure :: Int -> Parser Text
ensure !n = T.Parser $ \i0 a0 m0 kf ks ->
    if lengthAtLeast (unI i0) n
    then ks i0 a0 m0 (unI i0)
    else runParser (demandInput >> go n) i0 a0 m0 kf ks
  where
    go n' = T.Parser $ \i0 a0 m0 kf ks ->
        if lengthAtLeast (unI i0) n'
        then ks i0 a0 m0 (unI i0)
        else runParser (demandInput >> go n') i0 a0 m0 kf ks

ensure n创建一个继续要求更多粥Partial如果没有立即找到足够的输入，则输入（结果）。

你可能会失败

Prelude Data.Attoparsec.Text Data.Text> parseOnly (string (pack "module")) (pack "mox")
Left "not enough input"

预先告诉解析器它不会再获得任何输入（然后demandInputfromensure使它失败），或者稍后

Prelude Data.Attoparsec.Text Data.Text> parse (string (pack "module")) (pack "mox")
Partial _
Prelude Data.Attoparsec.Text Data.Text> feed it (pack "")
Fail "mox" ["demandInput"] "not enough input"

通过告诉Partial结果就是它，给它一个空的Text。

于 2013-01-11T23:02:07.053 回答