175

在 Windows 中，如何访问批处理文件运行时传递的参数？

例如，假设我有一个名为hello.bat. 当我hello -a在 Windows 命令行中输入时，如何让我的程序知道-a作为参数传入的？

4

5 回答 5

311

正如其他人已经说过的那样，通过命令行传递的参数可以在批处理文件中使用符号%1to访问%9。您还可以使用另外两个令牌：

  • %0是命令行中指定的可执行文件（批处理文件）名称。
  • %*是命令行中指定的所有参数——如果你想将参数转发给另一个程序，这非常有用。

除了简单地如何访问参数之外，还有许多重要的技术需要注意。

检查是否传递了参数

这是通过类似的结构来完成的IF "%~1"==""，当且仅当根本没有传递任何参数时才成立。请注意波浪字符，它会导致从%1; 的值中删除任何周围的引号。如果该值包含双引号，则如果没有波浪号，您将得到意外的结果，包括语法错误的可能性。

处理超过 9 个参数（或者只是让生活更轻松）

如果您需要访问超过 9 个参数，则必须使用命令SHIFT。此命令将所有参数的值移动一个位置，以便%0获取 的值%1，%1获取 的值%2等。%9获取第十个参数的值（如果存在），在调用之前无法通过任何变量获得SHIFT（输入命令SHIFT /?以获得更多选项）。

SHIFT当您想要轻松处理参数而不要求它们以特定顺序显示时，它也很有用。例如，脚本可以以任何顺序识别-a标志-b。在这种情况下解析命令行的一个好方法是

:parse
IF "%~1"=="" GOTO endparse
IF "%~1"=="-a" REM do something
IF "%~1"=="-b" REM do something else
SHIFT
GOTO parse
:endparse
REM ready for action!

该方案允许您解析非常复杂的命令行而不会发疯。

批量参数替换

对于表示文件名的参数，shell 提供了许多与处理无法以任何其他方式访问的文件相关的功能。使用以 开头的构造访问此功能%~。

例如，要获取作为参数传入的文件的大小，请使用

ECHO %~z1

要获取启动批处理文件的目录的路径（非常有用！），您可以使用

ECHO %~dp0

CALL /?您可以通过在命令提示符中键入来查看这些功能的全部范围。

于 2013-01-12T22:46:27.300 回答
59

在批处理文件中使用参数: %0 和 %9

批处理文件可以使用标记引用作为参数传入的单词：%0to %9。

%0 is the program name as it was called.
%1 is the first command line parameter
%2 is the second command line parameter
and so on till %9.

在命令行中传入的参数必须是字母数字字符并以空格分隔。由于%0是程序名，%0如果在引导时启动，则在 DOS 中 AUTOEXEC.BAT 将为空。

例子：

将以下命令放入名为的批处理文件中mybatch.bat：

@echo off
@echo hello %1 %2
pause

像这样调用批处理文件：mybatch john billy将输出：

hello john billy

为一个批处理文件获取超过 9 个参数，使用：%*

百分比星标记%*表示“其余参数”。您可以使用 for 循环来抓取它们，如此处所定义：

http://www.robvanderwoude.com/parameters.php

关于批处理参数分隔符的说明

批处理文件会忽略命令行参数中的某些字符，具体取决于 DOS 版本，是否“转义”，并且通常取决于它们在命令行中的位置：

commas (",") are replaced by spaces, unless they are part of a string in 
double quotes

semicolons (";") are replaced by spaces, unless they are part of a string in 
double quotes

"=" characters are sometimes replaced by spaces, not if they are part of a 
string in double quotes

the first forward slash ("/") is replaced by a space only if it immediately 
follows the command, without a leading space

multiple spaces are replaced by a single space, unless they are part of a 
string in double quotes

tabs are replaced by a single space

leading spaces before the first command line argument are ignored
于 2013-01-11T21:03:06.737 回答
10

@Jon 的:parse/:endparse计划是一个很好的开始，他对最初的通过表示感谢，但如果你认为 Windows 折磨人的批处理系统会让你轻松......好吧，我的朋友，你会感到震惊。我花了一整天的时间在这个恶魔上，经过许多痛苦的研究和实验，我终于设法为现实生活中的实用程序提供了一些可行的东西。

假设我们要实现一个实用程序foobar。它需要一个初始命令。它有一个可选参数--foo，它带有一个可选值（当然不能是另一个参数）；如果缺少该值，则默认为default. 它还有一个可选参数--bar，它采用必需的值。最后，它可以带一个--baz不允许值的标志。哦，这些参数可以按任何顺序出现。

换句话说，它看起来像这样：

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

复杂？不，这似乎是现实生活实用程序的典型。（git有人吗？）

事不宜迟，这里有一个解决方案：

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

是的，它真的那么糟糕。请参阅我在https://stackoverflow.com/a/50653047/421049上的类似帖子，其中我对逻辑中发生的事情以及我使用某些构造的原因进行了更多分析。

可怕。我今天必须学习的大部分内容。而且很痛。

于 2018-06-02T02:29:25.687 回答
5

批处理文件会在程序之后自动传递文本，只要它们是分配给它们的变量。它们按发送顺序传递；例如 %1 将是调用程序后发送的第一个字符串，等等。

如果你有 Hello.bat 并且内容是：

@echo off
echo.Hello, %1 thanks for running this batch file (%2)
pause

你通过命令调用批处理

hello.bat APerson241 %date%

您应该收到此消息：

您好，APerson241 感谢您运行此批处理文件 (01/11/2013)

于 2013-01-11T21:06:24.170 回答
3

使用变量，即.BAT变量并调用%0%9

于 2013-01-11T21:02:51.577 回答