2

我无法让 clojure defmacro 做我想做的事。我已将我的实际代码缩减为以下代码段。

这创造了一些接近我想要的东西。我试图根据传递给宏的参数有条件地插入（第一个 p#）或（第二个 p#）。

(defmacro mmz1 [t]
  `(map (fn [p#] (let [t1# (first p#)
                      t2# ~(if t `(first p#) `(second p#))]
                  (* t1# t2#)))
        [ [1 2] [3 4] ]))

(macroexpand-1 '(mmz1 false))

节目

(map
  (fn [p__18341__auto__]
    (let [t1__18342__auto__ (first p__18341__auto__)
          t2__18343__auto__ (second p__18340__auto__)]
      (* t1__18342__auto__ t2__18343__auto__)))
  [[1 2] [3 4]])

但是，请注意，这种形式的变量（第二个p_18340 _auto_ ）与匿名函数参数p_18341_auto_不匹配。因此，执行代码会导致错误，因为未定义第二个 var。我怎样才能让这些变量匹配？这就是我想要完成的。

出于测试目的，此代码完成了我想要的，但我不希望在结果宏代码中设置 t2# 的 (if) 形式。宏应该允许我这样做——不是吗？

(defmacro mmz0 [t]
  `(map (fn [p#] (let [t1# (first p#)
                      t2# (if ~t (first p#) (second p#))]
                  (* t1# t2#)))
        [ [1 2] [3 4] ]))

(macroexpand-1 '(mmz0 false))

节目

(map
  (fn [p__18387__auto__]
    (let [t1__18388__auto__ (first p__18387__auto__)
          t2__18389__auto__ (if false
                              (first p__18387__auto__)
                              (second p__18387__auto__))]
      (* t1__18388__auto__ t2__18389__auto__)))
  [[1 2] [3 4]])

并且代码的输出是预期的：

(mmz0 false) -> (2 12)
4

2 回答 2

3

解决方案之一

(defmacro mmz1 [t]
  `(map (fn [p#] (let [t1# (first p#)
                       t2# (~(if t 'first 'second) p#)]
                   (* t1# t2#)))
        [ [1 2] [3 4] ]))

更新。更通用的解决方案

(defmacro mmz1 [t]
  (let [trg-fn (if t 
                 `(fn [p#] (first p#)) 
                 `(fn [p#] (second p#)))]
    `(map (fn [p#] (let [t1# (first p#)
                         t2# (~trg-fn p#)]
                   (* t1# t2#)))
        [ [1 2] [3 4] ])))

您可以用更复杂的功能替换分支(fn [p#]...)。if

更新2。使用预定义函数形式参数的更简单的解决方案p

(defmacro mmz1 [t]
  (let [p `p#]
   `(map (fn [~p] (let [t1# (first ~p)
                        t2# ~(if t `(first ~p) `(second ~p))]
                    (* t1# t2#)))
         [ [1 2] [3 4] ])))
于 2013-01-11T03:45:05.780 回答
0

必须指出，这根本不需要是宏。

等效函数更具可读性和可组合性，因此我建议您使用它。

于 2013-01-11T06:28:01.323 回答