2

所以，我真的被困住了，开始认为这不是正确的方法。考虑这个字符串：“[APPLE|ORANGE] PEAR” 这里的逻辑应该是“如果 APPLE 在字符串中，给我它的颜色 ELSE 如果 ORANGE 在字符串中，给我它的颜色 ELSE 返回空字符串。现在总是返回 PEAR 颜色”。

我能够让Hello World正常工作。1. 我正在努力让 ANTLR 理解我的字符串中的条件逻辑。2. 我正在努力让 ANTLR 为每个标识符调用 getColor()。任何帮助或指导将不胜感激。我现在正气喘吁吁。

grammar Test;

@header {
  package org.mytest.Test;
}

@members {
    private String answer = "";

    private void getColor(String fruit)
    {
        //Use java reflection to get Fruit class and invoke method getColor()
        answer = fruit.color;
    }

}

 @lexer::header {
  package org.mytest.Test;
}


/*------------------------------------------------------------------
 * PARSER RULES
 *------------------------------------------------------------------*/

row returns [List<String> list]
@init {list = new ArrayList<String>();}
  :  a=value {list.add($a.val);} (WS b=value {list.add($b.val);})* (EOF)
  ;

conditionalString    returns [String color]:
                (
                a=IDENTIFIER (WS IDENTIFIER)* {getColor($a.text); } 
                )
                {$color=answer;};

//Get the text string for the matched identifier?
value returns [String val]  :  IDENTIFIER {val = $IDENTIFIER.text;}  ;


/*------------------------------------------------------------------
 * LEXER RULES
 *------------------------------------------------------------------*/

IDENTIFIER  :   ('A'..'Z')+;


WS : ( '\t' | ' ')+     { $channel = HIDDEN; } ;

理想的用法如下。“上下文”参数将是一些资源句柄。我会手动编辑构造函数以传递上下文，以便 ANTL 知道如何处理每个令牌。

TestLexer lex = new TestLexer(new ANTLRStringStream("[APPLE|ORANGE] PEAR"));
CommonTokenStream tok = new CommonTokenStream(lex);
TestParser par = new TestParser(context,tok);
System.out.println(par.conditionalString());
4

1 回答 1

1

这是我认为接近您要求的语法。它只处理您指定的情况：[id|id|id]是一个简单的条件，条件id之外的任何内容都按原样评估。

水果.g

grammar Fruit;

@parser::members { 

    private StringBuilder output = new StringBuilder();
    private java.util.HashMap<String, String> colors = new java.util.HashMap<String, String>();

    public void addColor(String fruit, String color){
        colors.put(fruit, color);
    }

    private void printColor(String fruit){
        if (colors.containsKey(fruit)){
            output.append(colors.get(fruit));
            output.append(" ");
        } else { 
            output.append("(no color for ").append(fruit).append(")");
        }
    }

    private void printColor(Token id){
        printColor(id.getText());
    }

    private void evaluateCondition(java.util.List<Token> tokens){
        for (Token token : tokens){
            String fruit = token.getText();
            if (colors.containsKey(fruit)){
                printColor(fruit);
                break;
            }
        }
    }
}

conditionalString returns [String result]
@after { result = output.toString();}
            : expr
            ;

expr        : cond_expr+
            ;

cond_expr   : ID
            {printColor($ID);}
            | LSQB values+=ID (OR values+=ID)* RSQB
            {evaluateCondition($values);}
            ;

OR          : '|';
LSQB        : '[';
RSQB        : ']';
ID          : ('A'..'Z')+;
WS          : ('\t'|' ')+ {skip();};

这里是测试类。存在解析器上的方法addColor以简化测试。例如，如果水果“ORANGE”的颜色为“orange”并且输入字符串是“ORANGE ORANGE”，那么输出应该是“orange orange”。

FruitTest.java

public class FruitTest {

    public static void main(String[] args) throws Exception {
        CharStream input = new ANTLRStringStream("[APPLE|ORANGE] PEAR");
        FruitLexer lexer = new FruitLexer(input);
        CommonTokenStream tokens = new CommonTokenStream(lexer);

        FruitParser parser = new FruitParser(tokens);

        parser.addColor("APPLE", "red");
        parser.addColor("ORANGE", "orange");
        parser.addColor("PEAR", "yellow");

        String result = parser.conditionalString();

        if (lexer.getNumberOfSyntaxErrors() > 0 || parser.getNumberOfSyntaxErrors() > 0){
            throw new Exception("Syntax errors encountered!");
        }

        System.out.println(result);
    }
}

测试用例 1：大量水果

  • 苹果=红色
  • 橙色 = 橙色
  • 梨 = 黄色

输入： [APPLE|ORANGE] PEAR
输出：red yellow

测试用例 2：大量水果

  • 橙色 = 橙色
  • 梨 = 黄色

输入： [APPLE|ORANGE] PEAR
输出：orange yellow

测试用例 3：水果少

  • 梨 = 黄色

输入： [APPLE|ORANGE] PEAR
输出：yellow

测试用例 4：绝食（未定义水果颜色）

输入： [APPLE|ORANGE] PEAR
输出：(no color for PEAR)

由于PEAR不是条件的一部分，因此需要对其进行定义。

于 2013-01-11T04:08:45.130 回答