4

基于这个问题： How can I get HTML source code from TWebBrowser

如果我使用具有 Unicode 代码页的 html 页面运行此代码，则结果是乱码，因为 TStringStream 在 D7 中不是 Unicode。该页面可能是 UTF8 编码或其他 (Ansi) 代码页编码的。

如何检测 TStream/IPersistStreamInit 是否为 Unicode/UTF8/Ansi？

对于此函数，我如何始终将正确的结果作为WideString返回？

function GetWebBrowserHTML(const WebBrowser: TWebBrowser): WideString;

如果我用 TMemoryStream 替换 TStringStream，并将 TMemoryStream 保存到文件中，一切都很好。它可以是 Unicode/UTF8/Ansi。但我总是想将流返回为 WideString：

function GetWebBrowserHTML(const WebBrowser: TWebBrowser): WideString;
var
  // LStream: TStringStream;
  LStream: TMemoryStream;
  Stream : IStream;
  LPersistStreamInit : IPersistStreamInit;
begin
  if not Assigned(WebBrowser.Document) then exit;
  // LStream := TStringStream.Create('');
  LStream := TMemoryStream.Create;
  try
    LPersistStreamInit := WebBrowser.Document as IPersistStreamInit;
    Stream := TStreamAdapter.Create(LStream,soReference);
    LPersistStreamInit.Save(Stream,true);
    // result := LStream.DataString;
    LStream.SaveToFile('c:\test\test.txt'); // test only - file is ok
    Result := ??? // WideString
  finally
    LStream.Free();
  end;
end;

编辑：我找到了这篇文章 - How to load and save documents in TWebBrowser in a Delphi-like way

这正是我需要的。但它仅适用于 Delphi Unicode 编译器 (D2009+)。阅读结论部分：

显然我们可以做的还有很多。有几件事立刻浮现在脑海。我们将一些 Unicode 功能和对非 ANSI 编码的支持改进为预 Unicode 编译器代码。如果文档字符集不是 ANSI，则使用早于 Delphi 2009 的任何内容编译的当前代码将无法将文档内容正确保存为字符串。

魔术显然在TEncoding类（TEncoding.GetBufferEncoding）中。但D7没有TEncoding。有任何想法吗？

4

1 回答 1

2

我使用GpTextStream来处理转换（应该适用于所有 Delphi 版本）：

function GetCodePageFromHTMLCharSet(Charset: WideString): Word;
const
  WIN_CHARSET = 'windows-';
  ISO_CHARSET = 'iso-';
var
  S: string;
begin
  Result := 0;
  if Charset = 'unicode' then
    Result := CP_UNICODE else
  if Charset = 'utf-8' then
    Result := CP_UTF8 else
  if Pos(WIN_CHARSET, Charset) <> 0 then
  begin
    S := Copy(Charset, Length(WIN_CHARSET) + 1, Maxint);
    Result := StrToIntDef(S, 0);
  end else
  if Pos(ISO_CHARSET, Charset) <> 0 then // ISO-8859 (e.g. iso-8859-1: => 28591)
  begin
    S := Copy(Charset, Length(ISO_CHARSET) + 1, Maxint);
    S := Copy(S, Pos('-', S) + 1, 2);
    if S = '15' then // ISO-8859-15 (Latin 9)
      Result := 28605
    else
      Result := StrToIntDef('2859' + S, 0);
  end;
end;

function GetWebBrowserHTML(WebBrowser: TWebBrowser): WideString;
var
  LStream: TMemoryStream;
  Stream: IStream;
  LPersistStreamInit: IPersistStreamInit;
  TextStream: TGpTextStream;
  Charset: WideString;
  Buf: WideString;
  CodePage: Word;
  N: Integer;
begin
  Result := ''; 
  if not Assigned(WebBrowser.Document) then Exit;
  LStream := TMemoryStream.Create;
  try
    LPersistStreamInit := WebBrowser.Document as IPersistStreamInit;
    Stream := TStreamAdapter.Create(LStream, soReference);
    if Failed(LPersistStreamInit.Save(Stream, True)) then Exit;
    Charset := (WebBrowser.Document as IHTMLDocument2).charset;
    CodePage := GetCodePageFromHTMLCharSet(Charset);
    N := LStream.Size;
    SetLength(Buf, N);
    TextStream := TGpTextStream.Create(LStream, tsaccRead, [], CodePage);
    try
      N := TextStream.Read(Buf[1], N * SizeOf(WideChar)) div SizeOf(WideChar);
      SetLength(Buf, N);
      Result := Buf;
    finally
      TextStream.Free;
    end;
  finally
    LStream.Free();
  end;
end;
于 2013-01-13T22:59:24.643 回答