7

我编写了一个批处理文件，它执行以下操作：

REM @ECHO OFF
rem %1 = coid
rem %2 = rpg location with ending /

rem get the path of this cmd script
SET SUBDIR=%~dp0

SET BKUPDIR=%SUBDIR%BACKUPS\
SET LOGFILE=%BKUPDIR%backup.log

ECHO ************************************************* >>%LOGFILE%
ECHO STARTING BACKUP FOR %1 AT %2 >>%LOGFILE%

FOR /f "skip=1" %%x in ('wmic os get localdatetime') DO IF NOT defined mydate SET mydate=%%x
SET filedate=%mydate:~0,14%
SET fullname=%BKUPDIR%%1_%FILEDATE%.ZIP

ECHO BKUPDIR: %BKUPDIR% >>%LOGFILE%
ECHO mydate: %mydate% >>%LOGFILE%
ECHO filedate: %filedate% >>%LOGFILE%
ECHO fullname: %fullname% >>%LOGFILE%
ECHO SUBDIR: %SUBDIR% >>%LOGFILE%

rem lets make sure the backup directory exists before starting
IF NOT EXIST %BKUPDIR% MD %BKUPDIR% >>%LOGFILE%

%SUBDIR%7z a -tzip %fullname%  %2%1*.d
IF ERRORLEVEL 255 ECHO user_stopped_the_process >>%LOGFILE%
IF ERRORLEVEL 8 ECHO not_enough_memory >>%LOGFILE%
IF ERRORLEVEL 7 ECHO command_line_error >>%LOGFILE%
IF ERRORLEVEL 2 ECHO fatal_error >>%LOGFILE%
IF ERRORLEVEL 1 ECHO ok_warnings >>%LOGFILE%

IF ERRORLEVEL 0 GOTO END
IF EXIST %fullname% DEL %fullname%

:END
ECHO FINISHING BACKUP FOR %1 >>%LOGFILE%
ECHO ************************************************* >>%LOGFILE%
set mydate=

我将文件保存为文件的%1创建日期/时间：

SSS_20130110133304.ZIP 
SSS_20130110133336.ZIP

我在任务调度程序中运行它以每天晚上运行。

我想避免目录中有太多 zip 文件，所以我想保留最后 30 个存在的 zip 文件。

我被困在这一点上。如何保留最近的 30 个 zip 文件，这样我就不会收到一堆垃圾的 zip 文件？

4

2 回答 2

11

这将列出从最新到最旧的 .zip 文件（按创建日期），跳过前 30 个文件。

for /f "skip=30 delims=" %%A in ('dir /a:-d /b /o:-d /t:c *.zip ^2^>nul') do if exist "%%~fA" echo "%%~fA"

只需在您想要实际删除文件时更改echo为。del:)

于 2013-01-10T20:56:47.093 回答
4

只关注这个问题——如何保留 30 个最新文件，并删除其余文件：

您可以dir > clean.lst使用正确的排序来执行 a，以便最新的文件位于clean.lst. 然后您可以使用该for命令跳过文件中的前 30 行，并删除第 30 个文件之后列出的文件。

考虑这个测试用例：

C:>md xyz
C:>cd xyz
c:\xyz>copy con genfiles.bat
@echo off
set _i=1
:loop
if %_i%==100 goto :EOF
echo.>%_i%.txt
set /a _i+=1
goto loop
^Z
        1 file(s) copied.

c:\xyz>genfiles
c:\xyz>del genfiles.bat

现在您在 XYZ 文件夹中有 99 个文本文件。

您可以像这样删除除 30 个最新的以外的所有内容：

C:\xyz>dir /b /o-d *.txt > clean.lst
C:\xyz>for /f "skip=30 delims=" %i in (clean.lst) do del "%i"
C:\xyz>del clean.lst

Adir只显示文本文件 70.txt - 99.txt 保留，其余已被删除。

对于您的批处理文件，我认为它看起来像这样：

cd /d %BKUPDIR%
dir /b /o-d *.zip > clean.lst
for /f "skip=30 delims=" %%i in (clean.lst) do del "%%i"
del clean.lst
于 2013-01-10T21:03:40.360 回答