1

我有这个 xml 文档：

<tags>
<w lemme="déclaration" pos="NOM">Déclaration</w>
<w lemme="du" pos="PRP:det">des</w>
<w lemme="droit" pos="NOM">droits</w>
<w lemme="de" pos="PRP">de</w>
<w lemme="le" pos="DET:ART">l'</w>
<w lemme="homme" pos="NOM">homme</w>
<w lemme="et" pos="KON">et</w>
<w lemme="," pos="PUN">,</w>
...
</tags>

我正在尝试使用 xsl 过滤掉文章和标点符号。像这里 <w lemme=","pos="PUN" >,</w> 和 <w lemme="de" pos="PRP" >de</w> <w lemme="le" pos="DET :ART">l'</w>。因此，我制作了以下样式表，该样式表有效，但将我的所有条件推广到所有标签，包括标签 <标签>。

<xsl:template match="*">
<xsl:choose>
<xsl:when test="contains(@pos,'PUN')"></xsl:when>
<xsl:when test="contains(@pos,'PRP')"></xsl:when>
<xsl:when test="contains(@pos,'DET')"></xsl:when>
<xsl:otherwise>
<xsl:copy>
<xsl:attribute name="lemme">
<xsl:value-of select="@lemme"/>
</xsl:attribute>
<xsl:attribute name="pos">
<xsl:value-of select="@pos"/>
</xsl:attribute>
<xsl:apply-templates/>
</xsl:copy>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

我有这个结果：

<tags lemme="" pos="">
<w lemme="déclaration" pos="NOM">Déclaration</w>
<w lemme="droit" pos="NOM">droits</w>
<w lemme="homme" pos="NOM">homme</w>
<w lemme="et" pos="KON">et</w>
<w lemme="citoyen" pos="NOM">citoyen</w>

所以它可以工作并且只显示我感兴趣的行，只是我不希望它也在第一行的 < tags > 标签中添加 lemme="" pos="" 。我应该在 xsl 中进行什么更改以使其仅使用 < w > 标签。我尝试了 < xsl:template match="w" > 但它没有生成有效的 xml。请帮忙？

4

2 回答 2

1

您应该使用标准身份转换，即此模板：

<xsl:template match="node()|@*">
  <xsl:copy>
    <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
</xsl:template>

您始终可以使用它来将所有内容从源复制到输出。异常由额外的模板处理，如下所示：

<xsl:template match="w[contains(@pos,'PUN')]
                    |w[contains(@pos,'PRP')]
                    |w[contains(@pos,'DET')]"/>

什么都不做。它只是匹配不需要的元素并防止身份转换模板匹配和复制它们。完整的样式表如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="w[contains(@pos,'PUN')]
                      |w[contains(@pos,'PRP')]
                      |w[contains(@pos,'DET')]"/>
</xsl:stylesheet>
于 2013-01-09T22:20:43.637 回答
0

有几种方法可以解决这个问题，但增加已有内容的一种方法是让一个规则匹配并输出标签元素，然后应用仅匹配 w 元素的第二个模板

首先，将此模板添加到您拥有的模板之前：

<xsl:template match="/tags">
<xsl:copy>
<xsl:apply-templates select="w"/>
</xsl:copy>
</xsl:template>

对于第二位，将您当前的模板更改为：

<xsl:template match="w">

为清楚起见，这里是完整的样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" encoding="utf-8" indent="yes"/>

    <xsl:template match="/tags">
        <xsl:copy>
            <xsl:apply-templates select="w"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="w">
        <xsl:choose>
            <xsl:when test="contains(@pos,'PUN')"></xsl:when>
            <xsl:when test="contains(@pos,'PRP')"></xsl:when>
            <xsl:when test="contains(@pos,'DET')"></xsl:when>
            <xsl:otherwise>
                <xsl:copy>
                    <xsl:attribute name="lemme">
                        <xsl:value-of select="@lemme"/>
                    </xsl:attribute>
                    <xsl:attribute name="pos">
                        <xsl:value-of select="@pos"/>
                    </xsl:attribute>
                    <xsl:apply-templates/>
                </xsl:copy>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

这产生了预期的结果：

<?xml version="1.0" encoding="utf-8"?>
<tags>
    <w lemme="déclaration" pos="NOM">Déclaration</w>
    <w lemme="droit" pos="NOM">droits</w>
    <w lemme="homme" pos="NOM">homme</w>
    <w lemme="et" pos="KON">et</w>
</tags>

希望这可以帮助。

于 2013-01-09T21:26:24.547 回答