6

我正在尝试学习如何使用程序集（NASM）创建 Dos .EXE 文件，手动构建标头并将文件组装为二进制文件。我的页面选项有问题（总页数和最后一页的字节数）。无论我设置的初始值有多小，程序都可以工作。

作为一种极端情况，即使设置 1 页 1 字节，以下程序也会起作用：

;
; the smallest possible "Hello, World!" .EXE (DOS MZ) file
; assemble with:
; nasm -f bin -w+all -O0 smallest_hello_exe.asm -o ASM.EXE
;

bits 16
cpu 8086

;
; by setting cs:ip=-10h:100h instead of 0h:0h inside the .EXE header
; (identical assignments), we achieve the following two advantages:
; 1) ds==cs, so no "push cs pop ds" is needed in order for ds:dx
; to point to the message string
; 2) we can exit by int 20h instead of int 21h, thus omitting the
; ah=4ch assignment
; (int 20h requires that cs points to the PSP segment)
;

;
; we do not the address calculations to take the .EXE header into account
; so we must subtract its length (20h) by an "org -20h"
; but, since ip will be 100h, we must also issue an "org 100h"
; and, since 0x100-0x20=0xE0...

org 0xE0        ; 100h for ip value - 20h for header



section .text align=1
;
; the MZ .EXE header structure
; 28 bytes long
; 1 pararaph equals 16 bytes
; 1 page equals 512 bytes
; suggested reading: int 21h,ah=4bh procedure
;
host_exe_header:
.signature: dw 'MZ'     ; the 'MZ' characters
.last_page_size: dw 1   ; number of used bytes in the final file page, 0 for all
.page_count: dw 1       ; number of file pages including any last partial page
.reloc: dw 0            ; number of relocation entries after the header
.paragraphs: dw 2       ; size of header + relocation table, in paragraphs
.minalloc: dw 0         ; minimum required additional memory, in paragraphs
.maxalloc: dw 0xFFFF    ; maximum memory to be allocated, in paragraphs
.in_ss: dw 0            ; initial relative value of the stack segment
.in_sp: dw 0xF000       ; initial sp value
.checksum: dw 0         ; checksum: 1's complement of sum of all words
.in_ip: dw 100h         ; initial ip value
.in_cs: dw -10h         ; initial relative value of the text segment
.offset: dw 0           ; offset of the relocation table from start of header
.overlay: dw 0          ; overlay value (0h = main program)

; pad header (its size in bytes must be a multiple of 16)
times (32-$+$$) db 0

mov dx,message
mov ah,09h              ; write string ds:dx to stdout
int 21h
int 20h

section .data align=1
message: db 'Hello, World!$'

section .bss align=1

尝试不同的程序大小，我得出的结论是 Dos 将每个页面的所有 512 字节都加载到内存中。如果是这样，最后一页中字节数的目的是什么？

它会干扰 .bss、堆栈数据和/或动态内存分配吗？

4

2 回答 2

4

绝对不会忽略总页数，甚至不希望最初加载所有文件的程序也会使用它。他们稍后会自己阅读必要的片段。该bytes in the last page字段可能会或可能不会被忽略，具体取决于操作系统版本。它也可以四舍五入到段落或磁盘扇区边界。您不应该依赖特定的行为并正确填写。

您的测试代码之所以有效，是因为它很小，并且您的特定操作系统已选择将足够多的代码加载到内存中。如果您使您的程序大于单个页面但仍在字段中指定1，则page count您的代码可能不会完全加载并且无法工作。我试过：

times (32-$+$$) db 0
times (512) nop
mov dx,message
mov ah,09h              ; write string ds:dx to stdout
int 21h
int 20h

如果page count为 1，则失败，但如果page count为 2（用于dosbox测试）则有效。

于 2013-01-10T18:08:53.573 回答
1

页计数字段由 DOS 使用，而不是由 Windows NT 使用。

NT 使用的 IMAGE_DOS_HEADER 仅有的两个字段是 e_magic（必须是 IMAGE_DOS_SIGNATURE）和 e_lfanew，它是从 IMAGE_DOS_HEADER 开始到包含 NT 加载器的所有信息的 IMAGE_NT_HEADERS 结构的小于 4MB 的偏移量。

于 2013-01-28T07:22:02.807 回答