3

说我有以下xml：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/*">
  <display>
    <xsl:for-each select="logline_t">
      <xsl:text disable-output-escaping="yes">&lt;</xsl:text> <xsl:value-of select="./line_1" <xsl:text disable-output-escaping="yes">&gt;</xsl:text>
      <xsl:text disable-output-escaping="yes">&lt;</xsl:text> <xsl:value-of select="./line_2" <xsl:text disable-output-escaping="yes">&gt;</xsl:text>
      <xsl:text disable-output-escaping="yes">&lt;</xsl:text> <xsl:value-of select="./line_3" <xsl:text disable-output-escaping="yes">&gt;</xsl:text>
    </xsl:for-each>
  </display>
</xsl:template>
</xsl:stylesheet>

有没有办法为文档中出现的所有 xsl:text 设置 disable-output-escaping="yes" ？

我知道有一个选项可以放置 < xsl:output method="text"/> 并且每次都像 & lt; 出现时，会出现一个<，但问题是有时在line_1、line_2或line_3的值中，有一个“$lt;” 我不想改变（也就是说，我只需要改变两者之间的任何东西）

这就是我想要完成的。我有这个xml：

<readlog_l>
 <logline_t>
  <hora>16:01:09</hora>
  <texto>Call-ID: 663903&lt;hola&gt;396@127.0.0.1</texto>
 </logline_t>
</readlog_l>

而这个翻译：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/*">
 <display>

  &lt;screen name="<xsl:value-of select="name(.)"/>"&gt;

  <xsl:for-each select="logline_t">
  &lt; field name="<xsl:for-each select="*"><xsl:value-of select="."/></xsl:for-each>" value="" type="label"/&gt;
  </xsl:for-each>

  &lt;/screen&gt;

 </display>
</xsl:template>

</xsl:stylesheet>

我希望这是输出：

<?xml version="1.0"?>
<display>

<screen name="readlog_l">

  <field name="16:01:09 Call-ID: 663903&lt;hola&gt;396@127.0.0.1 " value="" type="label">

</screen>
</display>

请注意，我需要字段名称中的“<”不要被转义，这就是我不能使用输出方法文本的原因。

另外，请注意，这是一个示例，翻译要大得多，所以这就是为什么我试图找出如何不为我需要的每个 '<' 或 '>' 编写禁用输出转义。

谢谢！

4

3 回答 3

2

感谢您澄清问题。在这种情况下，我相当确定没有必要禁用输出转义。XSLT 旨在完成您正在做的事情：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/*">
 <display>

  <screen name="{name(.)}">

  <xsl:for-each select="logline_t">
     <xsl:variable name="nameContent">
        <xsl:for-each select="*">
          <xsl:if test="position() > 1"><xsl:text> </xsl:text></xsl:if>                 
          <xsl:value-of select="."/>
        </xsl:for-each>
     </xsl:variable>
     <field name="{$nameContent}" value="" type="label" />
  </xsl:for-each>

  </screen>

 </display>
</xsl:template>

</xsl:stylesheet>

在这一点上我有点不清楚：请注意，我需要字段名称中的“<”不要被转义，这就是为什么我不能使用输出方法文本的原因。

你指的是哪个<？是“hola”周围的<和>吗？如果你让那些未转义的，你最终会得到无效的 XML。您的示例输出中的 name 属性看起来也有很多不在输入 XML 中的值。那些是从哪里来的？

于 2013-01-08T17:27:35.580 回答
2

鉴于您的预期输出，您根本不需要 doe 。这是一个不使用 doe 的可能解决方案，它基于模板而不是for-each：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" />

  <xsl:template match="/*">
    <display>
      <screen name="{name(.)}">
        <xsl:apply-templates select="logline_t"/>
      </screen>
    </display>
  </xsl:template>

  <xsl:template match="logline_t">
    <field value="" type="label">
      <xsl:attribute name="name">
        <xsl:apply-templates select="*" mode="fieldvalue"/>
      </xsl:attribute>
    </field>
  </xsl:template>

  <xsl:template match="*[last()]" mode="fieldvalue">
    <xsl:value-of select="." />
  </xsl:template>

  <xsl:template match="*" mode="fieldvalue">
    <xsl:value-of select="." />
    <xsl:text> </xsl:text>
  </xsl:template>

</xsl:stylesheet>
于 2013-01-09T13:33:40.437 回答
1

如果您想在所有内容上设置 doe，这表明您正在尝试“手动”生成标记。我不认为这是一个特别好的想法（实际上，我认为这是一个糟糕的想法），但如果这是你想做的，我会建议使用文本输出方法而不是 xml 输出方法。这样，不会发生特殊字符的转义，因此不需要禁用它。

于 2013-01-08T17:21:02.417 回答