2

我对下面的脚本有一些麻烦。

proc checkUser {userip} {
    set search "show users | include "
    set search_cmd [concat $search $userip]
    exp_send "$search_cmd\r"

    expect {
        -re "Vi.*" {

            set oui "uei.opennms.org/services/passiveServiceStatus"
            set host "localhost"
            set iface "--interface $userip"
            set service "--service Test"
            set parm1 "--parm 'passiveNodeLabel [getNodeName $userip]'"
            set parm2 "--parm 'passiveIpAddr $userip'"
            set parm3 "--parm 'passiveServiceName Test'" 
            set parm4 "--parm 'passiveStatus Up'"

            send_user [ exec perl /opt/opennms/bin/send-event.pl $oui,$host,$iface,$service,$parm1,$parm2,$parm3,$parm4 ]
            #send_user [ exec [pwd]]

        }
    }
}

整个 Expect 脚本执行没有错误，但是调用的 perl 脚本似乎没有执行，但是当我在 bash 中使用相同的参数运行 perl 脚本时，它会执行它应该做的事情。

这是从 Expect 中调用 perl 脚本的正确方法吗？

提前致谢。

4

1 回答 1

3

编写的程序会将参数作为一个大参数传递给 Perl 脚本，参数之间用逗号分隔。虽然这通常是合法的，但它可能不是 Perl 程序想要的！取而代之的是，在两者之间放置空格，以便这些值在 Tcl 级别是单独的参数，并且它们也将在 Perl 级别成为单独的命令行参数：

exec perl /opt/opennms/bin/send-event.pl $oui $host $iface $service $parm1 $parm2 $parm3 $parm4

此外，似乎每个 Tcl 变量都有多个参数，并且您试图在其中使用 shell 引用。那就更不对了。你最好写这样的代码：

expect {
    -re "Vi.*" {
        set oui "uei.opennms.org/services/passiveServiceStatus"
        set host "localhost"

        send_user [ exec perl /opt/opennms/bin/send-event.pl $oui $host \
                --interface $userip \
                --service "Test" \
                --parm "passiveNodeLabel [getNodeName $userip]" \
                --parm "passiveIpAddr $userip" \
                --parm "passiveServiceName Test" \
                --parm "passiveStatus Up" ]
    }
}

每个参数字在 Tcl 中都是它自己的字；我已经加入了反斜杠换行符以使事情更清晰。我们使用双引号，这样它们可以在处理替换的同时嵌入空格，但是如果你需要一些奇怪的东西，那么请放入{大括号}或使用反斜杠。

于 2013-01-08T09:58:32.410 回答