43

我正在 CMake 中构建一个静态库，它依赖于许多其他静态库。我希望它们都包含在输出 .lib/.a 文件中，这样我就可以将一个大的 lib 文件发送给客户。在 Visual Studio 2010 中，有一个选项"Link Library Dependencies"正是这样做的。

但我在 CMake 中找不到如何做到这一点。您可以通过 CMake 设置此标志，还是以其他方式获得相同的结果？我已经尝试过 target_link_libraries(...) 和 add_dependencies(...)，但 CMake 似乎只是忽略了静态库的这一行。

4

2 回答 2

21

好的，所以我有一个解决方案。首先，重要的是要认识到静态库不会将其他静态库链接到代码中。必须创建一个组合库，在 Linux 上可以使用ar. 有关更多信息，请参阅将静态库链接到其他静态库。

考虑两个源文件：

测试1.c：

 int hi()
 {
   return 0;
 }

测试2.c：

int bye()
{
  return 1;
}

该CMakeLists.txt文件是创建两个库，然后创建一个组合库，如下所示：

project(test)

    add_library(lib1 STATIC test1.c)
    add_library(lib2 STATIC test2.c)

    add_custom_target(combined ALL
      COMMAND ${CMAKE_AR} rc libcombined.a $<TARGET_FILE:lib1> $<TARGET_FILE:lib2>)

在这种情况下，命令的选项与ar平台相关，尽管CMAKE_AR变量与平台无关。我会四处寻找是否有更通用的方法来做到这一点，但这种方法适用于使用ar.

基于如何设置 CMAKE_AR 的选项？，看起来更好的方法是：

add_custom_target(combined ALL
   COMMAND ${CMAKE_CXX_ARCHIVE_CREATE} libcombined.a $<TARGET_FILE:lib1> $<TARGET_FILE:lib2>)

这应该与平台无关，因为这是 CMake 用于在内部创建档案的命令结构。当然，您要传递给存档命令的唯一选项是rc这些选项硬连线到 CMake 中以用于该ar命令。

于 2013-01-07T17:13:08.223 回答
14

我想通过提供我的CMakeLists.txt文件来增强其他解决方案，该文件在构建依赖项方面也确实有效。

滥用 CMake 的解决方案

cmake_minimum_required(VERSION 2.8)

add_library(lib1 test1.cpp)
add_library(lib2 test2.cpp)
include_directories(${CMAKE_CURRENT_DIR})
add_executable(mainexec main.cpp)
target_link_libraries(mainexec combinedLib)  # Important to place before add_custom_target

set(LIBNAME "combinedLib.lib")

add_custom_command(
    OUTPUT ${LIBNAME}
    COMMAND lib.exe /OUT:${LIBNAME} $<TARGET_FILE:lib1> $<TARGET_FILE:lib2>
    DEPENDS lib1 lib2
    COMMENT "Combining libs..."
)

add_custom_target(combinedLib
    DEPENDS ${LIBNAME}
)

请注意，到目前为止，此解决方案适用于 Visual Studio，但我想它可以兼容多平台。我可以想象以下版本可能适用于基于 Unix 的平台：

set(LIBNAME "libCombinedLib.a")

add_custom_command(
    OUTPUT ${LIBNAME}
    COMMAND ar -rcT ${LIBNAME} $<TARGET_FILE:lib1> $<TARGET_FILE:lib2>
    DEPENDS lib1 lib2
    COMMENT "Combining libs..."
)

请注意，这些解决方案会以某种方式滥用 CMake，因为如果您在声明target_link_libraries之后进行调用，它会抱怨 UTILITY 类型的目标（而不是 STATIC 或 SHARED） 。add_custom_target

CMake 目标声明兼容的解决方案

为了使其符合 CMake，您可以将 `target_link_libraries' 调用替换为

target_link_libraries(mainexec ${LIBNAME})
add_dependencies(mainexec combinedLib)

就我而言，它并不完全令人满意，因为尽管它希望所有依赖项都由调用处理，但它mainexec必须知道。combinedLibtarget_link_libraries

耦合较少的替代解决方案

进一步研究导入的目标，我最终找到了解决我最后一个问题的解决方案：

cmake_minimum_required(VERSION 2.8)

add_library(lib1 test1.cpp)
add_library(lib2 test2.cpp)
include_directories(${CMAKE_CURRENT_DIR})
add_executable(mainexec main.cpp)

set(LIBNAME "combinedLib.lib")

add_custom_command(
    OUTPUT ${LIBNAME}
    COMMAND lib.exe /OUT:${LIBNAME} $<TARGET_FILE:lib1> $<TARGET_FILE:lib2>
    DEPENDS lib1 lib2
    COMMENT "Combining libs..."
)

add_custom_target(combinedLibGenerator
    DEPENDS ${LIBNAME}
)

add_library(combinedLib STATIC IMPORTED)
set_property(TARGET combinedLib PROPERTY IMPORTED_LOCATION ${LIBNAME})
add_dependencies(combinedLib combinedLibGenerator)

target_link_libraries(mainexec combinedLib)

如果您打算模块化整个 add GLOBALafterSTATIC IMPORTED以使导入的目标全局可见。

便携式 CMake 解决方案

在当前的 CMake 版本中，CMake 完全支持传递依赖和接口库。然后一个接口库可以“链接”到其他库，而这个接口库又可以“链接”到其他库。为什么要引号？虽然这很好用，但这实际上并没有创建一个物理的组合库，而是为“子库”集创建了一种别名。这仍然是我们最终需要的解决方案，这就是我想在这里添加它的原因。

add_library(combinedLib INTERFACE)
target_link_libraries(combinedLib INTERFACE lib1 lib2)

target_link_libraries(mainexec combinedLib)

就是这样！

于 2015-10-01T13:35:29.097 回答