2

我目前正在尝试将以下循环转换为 cython：

cimport numpy as np
cimport cython
@cython.boundscheck(False) # turn of bounds-checking for entire function
def Interpolation(cells, int nmbcellsx):
    cdef np.ndarray[float, ndim=1] x,y,z
    cdef int i,j,len
    for i in range(nmbcellsx):
      x = cells[i].x
      y = cells[i].y
      z = cells[i].z
      len = x.size
      for j in range(len):
         x[j] = x[j] * y[j] * z[j]

    return 0

到目前为止，一切看起来都还不错，但是对 cells[i].* 的访问仍然需要 python 调用。这可以防止 i-loop 的并行化。

这是一个 cython 反馈（使用 cython -a 生成）：

cython -a 反馈

因此问题是：如何删除这些 python 回调（即，使第 9-12 行变为白色）？

当我尝试像这样添加 Cell 的类型时：

cimport numpy as np
cimport cython

cdef class cell_t:
   cdef np.ndarray x,y,z

@cython.boundscheck(False) # turn of bounds-checking for entire function
def Interpolation(np.ndarray[cell_t,ndim=1] cells, int nmbcellsx):
    cdef np.ndarray[float, ndim=1] x,y,z
    cdef int i,j,len
    for i in range(nmbcellsx):
      x = cells[i].x
      y = cells[i].y
      z = cells[i].z
      len = x.size
      for j in range(len):
         x[j] = x[j] * y[j] * z[j]

    return 0

我收到以下 cython 错误：dtype must be "object", numeric type or a struct（它抱怨声明中的 cell_t）

非常感谢。

4

2 回答 2

2

使用Typed Memoryview怎么样？

cimport cython

cdef class cell_t:
    cdef public float[:] x, y, z

    def __init__(self, x, y, z):
        self.x = x
        self.y = y
        self.z = z


@cython.boundscheck(False) # turn of bounds-checking for entire function
def Interpolation(cell_t[:] cells, int nmbcellsx):
    cdef float[:] x,y,z
    cdef int i,j,length
    cdef cell_t cell
    for i in range(nmbcellsx):
        cell = cells[i]
        x = cell.x
        y = cell.y
        z = cell.z
        length = len(x)
        for j in range(length):
            x[j] = x[j] * y[j] * z[j]
    return 0

这是测试代码：

import numpy as np
from cells import cell_t, Interpolation

x = np.array([1,2,3], np.float32)
y = np.array([4,5,6], np.float32)
z = np.array([7,8,9], np.float32)
c1 = cell_t(x, y, z)

x = np.array([1,1,1,1,1], np.float32)
y = np.array([2,2,2,2,2], np.float32)
z = np.array([3,3,3,3,3], np.float32)
c2 = cell_t(x, y, z)

cells = np.array([c1, c2], object)

Interpolation(cells, 2)

print c1.x.base
print c2.x.base

和输出：

[  28.   80.  162.]
[ 6.  6.  6.  6.  6.]
于 2013-01-07T04:23:26.473 回答
2

您没有告诉Cython参数的类型，cells因此它将使用Python查找方法。尝试将定义更改为以下内容：

def Interpolation(np.ndarray cells, int nmbcellsx):

这将告诉Cython它正在获取ndarray类型，因此可以使用C访问。

于 2013-01-06T22:45:25.660 回答