88

我在带有 Windows SDK 和 NMake Makefiles 的 Windows 上使用 CMake。

默认情况下，它使用/MD编译器开关进行编译。

如何将其更改为使用/MT开关进行编译？

4

6 回答 6

104

您可以修改CMAKE_CXX_FLAGS_<Build Type>和/或CMAKE_C_FLAGS_<Build Type>变量：

set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MT")
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")

如果您的 CMake 标志已经包含/MD，您可以确保在插入的点之后/MD执行上述命令（稍后添加/MT覆盖冲突的现有选项），或者您可以从头开始设置标志：

set(CMAKE_CXX_FLAGS_RELEASE "/MT")
set(CMAKE_CXX_FLAGS_DEBUG "/MTd")

或者，您可以通过执行以下操作分别用and替换现有的/MD和/MDd值：/MT/MTd

set(CompilerFlags
        CMAKE_CXX_FLAGS
        CMAKE_CXX_FLAGS_DEBUG
        CMAKE_CXX_FLAGS_RELEASE
        CMAKE_C_FLAGS
        CMAKE_C_FLAGS_DEBUG
        CMAKE_C_FLAGS_RELEASE
        )
foreach(CompilerFlag ${CompilerFlags})
  string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
endforeach()
于 2013-01-05T14:44:28.827 回答
85

MSVC_RUNTIME_LIBRARYCMake 最终在 3.15 版中使用target 属性添加了对此的适当支持：

cmake_minimum_required(VERSION 3.15)
cmake_policy(SET CMP0091 NEW)
project(my_project)

add_executable(foo foo.c)
set_property(TARGET foo PROPERTY
             MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")

您还可以通过设置CMAKE_MSVC_RUNTIME_LIBRARY变量来指定全局默认值。

于 2019-06-07T08:23:36.493 回答
10

似乎对于Visual Studio 15 2017和CMake 3.12，替换/MD为的方法/MT是将此代码段添加到 CMakeLists.txt 文件中：

if(MSVC)
    add_compile_options(
        $<$<CONFIG:>:/MT> #---------|
        $<$<CONFIG:Debug>:/MTd> #---|-- Statically link the runtime libraries
        $<$<CONFIG:Release>:/MT> #--|
    )
endif()

我在官方 CMake 存储库中找到了这个解决方案：https ://gitlab.kitware.com/cmake/cmake/issues/18390

于 2020-03-25T07:55:49.070 回答
2

我必须使用set( ... CACHE ... FORCE)来覆盖 MSVC 的默认缓存。

如果我不使用这种方法，MSVC 仍然会输出/MD选项。

set(CompilerFlags
        CMAKE_CXX_FLAGS
        CMAKE_CXX_FLAGS_DEBUG
        CMAKE_CXX_FLAGS_RELEASE
        CMAKE_CXX_FLAGS_MINSIZEREL
        CMAKE_CXX_FLAGS_RELWITHDEBINFO
        CMAKE_C_FLAGS
        CMAKE_C_FLAGS_DEBUG
        CMAKE_C_FLAGS_RELEASE
        CMAKE_C_FLAGS_MINSIZEREL
        CMAKE_C_FLAGS_RELWITHDEBINFO
        )
foreach(CompilerFlag ${CompilerFlags})
    string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
    set(${CompilerFlag} "${${CompilerFlag}}" CACHE STRING "msvc compiler flags" FORCE)
    message("MSVC flags: ${CompilerFlag}:${${CompilerFlag}}")
endforeach()
于 2019-06-10T05:15:25.137 回答
2

查看ucm_set_runtime - 此宏将替换静态或动态运行时的标志 - 要查看效果，请使用ucm_print_flags（也可查看此Stack Overflow 问题）。

于 2016-10-05T20:51:59.097 回答
0

从 cmacke 3.15 开始，您可以使用MSVC_RUNTIME_LIBRARY. 见https://cmake.org/cmake/help/latest/prop_tgt/MSVC_RUNTIME_LIBRARY.html

于 2021-12-20T09:53:37.737 回答