7

我正在尝试使用ios-cmake生成针对 iOS 的 Xcode 项目。但是，它找不到线程。这是一个用于演示的简单 CMake 脚本：

CMAKE_MINIMUM_REQUIRED (VERSION 2.8)
PROJECT (MyCITest)

SET (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules")

########################
# EDIT: I've also tried adding the lines below prior to posting this question, 
# but there doesn't seem to be any effect.
# (http://stackoverflow.com/questions/8386897)

SET (CMAKE_REQUIRED_INCLUDES ${CMAKE_IOS_SDK_ROOT}/usr ${CMAKE_IOS_SDK_ROOT}/usr/include)
SET (CMAKE_CXX_FLAGS "--sysroot=${CMAKE_IOS_SDK_ROOT} ${CMAKE_CXX_FLAGS}")
SET (CMAKE_C_FLAGS "--sysroot=${CMAKE_IOS_SDK_ROOT} ${CMAKE_C_FLAGS}")

########################

FIND_PACKAGE (ZLIB REQUIRED)
FIND_PACKAGE (LibXml2 REQUIRED)
FIND_PACKAGE (Threads REQUIRED)

从终端运行 CMake：

cmake .. -DCMAKE_TOOLCHAIN_FILE=../cmake/toolchains/iOS.cmake -GXcode

这是我得到的输出：

-- Toolchain using default iOS SDK: /Applications/Xcode.app/Contents/Developer/Platforms/iPhoneOS.platform/Developer/SDKs/iPhoneOS6.0.sdk
-- Found ZLIB: /Applications/Xcode.app/Contents/Developer/Platforms/iPhoneOS.platform/Developer/SDKs/iPhoneOS6.0.sdk/usr/lib/libz.dylib (found version "1.2.5") 
-- Found LibXml2: /Applications/Xcode.app/Contents/Developer/Platforms/iPhoneOS.platform/Developer/SDKs/iPhoneOS6.0.sdk/usr/lib/libxml2.dylib (found version "2.7.8") 
-- Looking for include file pthread.h
-- Looking for include file pthread.h - not found
CMake Error at cmake/modules/FindPackageHandleStandardArgs.cmake:97 (MESSAGE):
  Could NOT find Threads (missing: Threads_FOUND)
Call Stack (most recent call first):
  cmake/modules/FindPackageHandleStandardArgs.cmake:288 (_FPHSA_FAILURE_MESSAGE)
  cmake/modules/FindThreads.cmake:166 (FIND_PACKAGE_HANDLE_STANDARD_ARGS)
  CMakeLists.txt:8 (FIND_PACKAGE)


-- Configuring incomplete, errors occurred!

我已经三重检查了 pthread.h 位于 中/Applications/Xcode.app/Contents/Developer/Platforms/iPhoneOS.platform/Developer/SDKs/iPhoneOS6.0.sdk/usr/include，此外，它位于 ZLib 和 LibXML2 没有问题，所以我不确定我做错了什么。

> cmake --version
cmake version 2.8.10.2
4

7 回答 7

11

这些解决方案似乎都不起作用。我发现唯一对我有用的是设置 FindThreads.cmake 设置的变量。换句话说，在您的工具链文件中定义以下内容：

set(CMAKE_THREAD_LIBS_INIT "-lpthread")
set(CMAKE_HAVE_THREADS_LIBRARY 1)
set(CMAKE_USE_WIN32_THREADS_INIT 0)
set(CMAKE_USE_PTHREADS_INIT 1)
于 2015-09-24T22:21:08.173 回答
2

问题确实是由于调用try_compileFindThreads.cmake 失败所致。但对我来说设置CMAKE_CXX_COMPILER_WORKS是不够的。相反，我将执行的测试类型try_compile从尝试构建可执行文件更改为尝试构建静态库，方法是将其放入工具链文件中：

set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)
于 2018-12-04T17:00:04.727 回答
1

事实证明，iOS 工具链目前不支持TRY_COMPILE，由 使用CheckIncludeFiles.cmake，而后者又由FindThreads.cmake. 工具链当前设置为跳过TRY_COMPILE使用：

set (CMAKE_CXX_COMPILER_WORKS TRUE)
set (CMAKE_C_COMPILER_WORKS TRUE)

参考：http ://code.google.com/p/ios-cmake/issues/detail?id=1&can=1

于 2013-01-07T14:56:59.640 回答
1

您可以使用工具链中的下一个变量来修复try_compile命令：

# toolchain.cmake    
set(CMAKE_MACOSX_BUNDLE YES)
set(CMAKE_OSX_SYSROOT "iphoneos")
set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer")
set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.example")

和简约的例子：

# CMakeLists.txt
cmake_minimum_required(VERSION 2.8)
project(Foo)

find_package(Threads REQUIRED)
add_executable(foo foo.cpp)

生成输出：

> cmake -H. -B_builds -DCMAKE_TOOLCHAIN_FILE=toolchain.cmake -GXcode
...    
-- Looking for include file pthread.h
-- Looking for include file pthread.h - found
-- Looking for pthread_create
-- Looking for pthread_create - found
-- Found Threads: TRUE
...
于 2014-06-24T07:18:41.153 回答
1

[2019 年 9 月] 修复 XCode 11 和 iOS 13

正如这里所解释的。

需要使用XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED而不是CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED下面来完成这项工作：

set(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES "XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED")
set(XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED "NO")

find_package(Threads REQUIRED)

unset(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES)
unset(XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED)

[2019 年 8 月]：来自 CMake 问题跟踪器的信息

该问题已在此处讨论并由@alcroito 解释。它不使用自定义 ios-cmake 工具链，而是使用新的原生 iOS 工具链（CMake 3.14+），但问题是一样的。

问题的来源

使用 Xcode 生成器时，它会默认尝试对应用程序进行签名。查找时Threads，CMake 调用FindThreads.cmake将调用TRY_COMPILEXcode 将尝试签名并失败的测试。

适当的解决方案：

禁用try_compile内部签名FindThreads（见此处）：

set(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED")
set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED "NO")

find_package(Threads REQUIRED)

unset(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES)
unset(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED)

此线程中的其他解决方案

  1. 制作该try_compile静态的二进制文件，它不会被签名（见这里）。这不是很好，因为它应该是可执行文件而不是静态库。

  2. 传递适当的信息以便能够签署try_compile可执行文件（参见此处）。这实际上对我不起作用。

  3. 跳过try_compile（见此处）：不太安全，因为您将跳过所有编译器测试。那对我也不起作用。

  4. Threads通过覆盖做什么来硬编码FindThreads（见这里）：相当肮脏的解决方法。

于 2019-08-29T13:38:21.017 回答
-1

顺便提一下，我在项目中也遇到了同样的问题。我注释掉了这一find_package(Threads REQUIRED)行并生成了 Xcode proejct。编译的代码没有错误。也许 Xcode 可以自动与 posix 线程库链接。

于 2015-12-10T06:48:34.970 回答
-1

对我来说，解决方案是结合我面前的 2 个答案。注释掉禁用的 2 行try_compile

# Skip the platform compiler checks for cross compiling
set (CMAKE_CXX_COMPILER_WORKS TRUE)
set (CMAKE_C_COMPILER_WORKS TRUE)

然后将其添加到 IOS.cmake 工具链文件的顶部。

set(MACOSX_BUNDLE_GUI_IDENTIFIER com.example)
set(CMAKE_MACOSX_BUNDLE YES)
set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer")
于 2016-03-10T06:09:16.993 回答