5

我喜欢使用 Google Docs 函数 =importxml() 但想知道 Excel 2010 中是否有类似的功能？我似乎找不到让程序自动从链接的 XML 文件中提取数据的方法。

例如，我希望能够设置一个标题为“项目名称”的列，然后让下一列将上一列中用户输入的项目名称附加到此 url

http://util.eveuniversity.org/xml/itemLookup.php?name=

然后解析生成的 XML 文件以返回类型 ID。这是在谷歌文档中使用

=importxml(concatenate("http://util.eveuniversity.org/xml/itemLookup.php?name=",A3);"//itemLookup/typeID")

A3 是具有项目名称的列，在本例中为 Tritanium，并从生成的 XML 文件中导入数据

http://util.eveuniversity.org/xml/itemLookup.php?name=Tritanium

它返回值 34。

我有一个大约 20 个项目名称的列表，每次打开文件时，谷歌文档都会自动更新项目 ID。Excel 2010 有没有办法复制这个功能？

谢谢！

将要

4

4 回答 4

5

问题是从2013年开始的，已经过去了一段时间......

在 Excel 2013 中，有一个功能WEBSERVICE来加载 XML 文档，这正是您想要的。

还有 FILTERXML 可以使用 XPath 搜索加载的 XML 文档。

于 2015-04-24T19:33:53.323 回答
3

您将需要编写自己的 UDF。

一种方法是使用MSXML2库，如下所示：

Function GetData(sName As String, sItem As String, Optional sURL = "") As Variant
    Dim oHttp As New MSXML2.XMLHTTP60
    Dim xmlResp As MSXML2.DOMDocument60
    Dim result As Variant
    On Error GoTo EH

    If sURL = "" Then
        sURL = "http://util.eveuniversity.org/xml/itemLookup.php?name="
    End If

    'open the request and send it'
    oHttp.Open "GET", sURL & sName, False
    oHttp.Send

    'get the response as xml'
    Set xmlResp = oHttp.responseXML
    ' get Item'
    GetData = xmlResp.getElementsByTagName(sItem).Item(0).Text

    ' Examine output of these in the Immediate window'
    Debug.Print sName
    Debug.Print xmlResp.XML

CleanUp:
    On Error Resume Next
    Set xmlResp = Nothing
    Set oHttp = Nothing
Exit Function
EH:
    GetData = CVErr(xlErrValue)
    GoTo CleanUp
End Function

像这样调用它（其中A5包含 required typeName）

=GetData(A5, "typeID")
于 2013-01-05T00:20:27.053 回答
2 
Function ImportXML(url As String, query As String)

    Dim document    As MSXML2.DOMDocument60
    Dim http        As New MSXML2.XMLHTTP60

    http.Open "GET", url, False
    http.send

    Set document = http.responseXML

    ImportXML = document.SelectSingleNode(query).nodeTypedValue

End Function
于 2014-02-06T08:47:37.003 回答
0

数据菜单上的“来自网络”功能将在线数据直接拉入电子表格。XML 数据导入也可在 From Other Sources 子菜单下使用，该子菜单也列在数据菜单中。

创建的连接通过数据菜单上的连接对话框进行管理。

在创建“来自 Web”连接时使用记录宏的示例代码：

Sub Macro1()
' Macro1 Macro
With ActiveSheet.QueryTables.Add(Connection:= _
        "URL;http://en.wikipedia.org/wiki/Microsoft_Excel" _
        , Destination:=Range("$A$1"))
        .Name = _
        "?affID=110195&tt=270912_7a_3912_6&babsrc=HP_ss&mntrId=3e2fc48700000000000088532eb428ec"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .BackgroundQuery = True
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .WebSelectionType = xlEntirePage
        .WebFormatting = xlWebFormattingNone
        .WebPreFormattedTextToColumns = True
        .WebConsecutiveDelimitersAsOne = True
        .WebSingleBlockTextImport = False
        .WebDisableDateRecognition = False
        .WebDisableRedirections = False
        .Refresh BackgroundQuery:=False
    End With
End Sub
于 2013-01-06T01:33:41.653 回答