3

本质上，这是一个关于 Pascal (FPC) 中递归数据结构的问题。因为我想实现一个像 SICP 第 4 章中所示的 Scheme 解释器，所以这个问题也可能与 Schemers 有关。:)

S 表达式应表示为标记数据。到目前为止，我已经构建了一个变体记录，它表示数字和对。希望代码可读且不言自明：

program scheme;

type
   TTag = (ScmFixnum, ScmPair);
   PScmObject = ^TScmObject;
   TScmObject = record
      case ScmObjectTag: TTag of
         ScmFixnum: (ScmObjectFixnum: integer);
         ScmPair: (ScmObjectCar, ScmObjectCdr: PScmObject);
      end;

var
   Test1: TScmObject;
   Test2: TScmObject;
   Test3: TScmObject;

function MakeFixnum(x: integer): TScmObject;
var
   fixnum: TScmObject;
begin
   fixnum.ScmObjectTag := ScmFixnum;
   fixnum.ScmObjectFixnum := x;
   MakeFixnum := fixnum;
end;

function MakePair(car, cdr: PScmObject): TScmObject;
var
   pair: TScmObject;
begin
   pair.ScmObjectTag := ScmPair;
   pair.ScmObjectCar := car;
   pair.ScmObjectCdr := cdr;
   MakePair := pair;
end;

begin
   Test1 := MakeFixnum(7);
   writeln('Test1, Tag: ', Test1.ScmObjectTag,
           ', Content: ', Test1.ScmObjectFixnum);
   Test2 := MakeFixnum(9);
   writeln('Test2, Tag: ', Test2.ScmObjectTag,
           ', Content: ', Test2.ScmObjectFixnum);
   Test3 := MakePair(Test1, Test2);
end.

但是，编译代码会产生如下错误：

$ fpc scheme.pas
(...)
Compiling scheme.pas
scheme.pas(43,34) Error: Incompatible type for arg no. 2: Got "TScmObject", expected "PScmObject"
scheme.pas(45) Fatal: There were 1 errors compiling module, stopping
Fatal: Compilation aborted

很明显，函数中存在错误MakePair。但我还不明白我到底做错了什么。任何帮助表示赞赏。:)

4

2 回答 2

7

MakePair函数定义如下：

function MakePair(car, cdr: PScmObject): TScmObject;

请注意，它接收两个类型的指针PScmObject。然后你这样称呼它：

MakePair(Test1, Test2);

但是Test1和Test2属于 类型TScmObject。所以传递的实际参数是不兼容的，就像编译器说的那样。

您需要将指针传递给这些记录：

MakePair(@Test1, @Test2);

从长远来看，您需要注意这些记录的生命周期。您需要在堆上分配并且没有垃圾收集我怀疑您将进入一个痛苦的世界，试图跟踪谁拥有这些记录。也许您可以考虑使用接口引用计数来管理生命周期。

于 2013-01-04T21:03:18.050 回答
4

该过程需要一个指向记录的指针，而不是记录本身。

您可以在调用点使用@ (at) 运算符动态创建指向记录的指针，从而满足编译器类型检查：

begin
   Test1 := MakeFixnum(7);
   writeln('Test1, Tag: ', Test1.ScmObjectTag,
           ', Content: ', Test1.ScmObjectFixnum);
   Test2 := MakeFixnum(9);
   writeln('Test2, Tag: ', Test2.ScmObjectTag,
           ', Content: ', Test2.ScmObjectFixnum);
   Test3 := MakePair(@Test1, @Test2);
end.
于 2013-01-04T21:04:06.043 回答