1

我正在寻找 1.0 XSLT 转换，它会传播非空单元格，直到找到一个新单元格。我的输入：

<table>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value1</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value2</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
</table>

预期输出：

<table>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value1</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value1</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value1</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value2</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value2</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value2</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value2</column_1>
    <column_2></column_2>
</row>
</table>

我曾尝试使用previous::row[1]/column_1，但最终只有一个副本。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>
<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>
<xsl:template name="replace-value">
    <xsl:param name="value"/>
    <xsl:copy>
        <xsl:value-of select="$value"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="//column_1">
    <xsl:choose>
        <xsl:when test=".=''">
            <xsl:call-template name="replace-value">
                <xsl:with-param name="value" select="preceding::row[1]/column_1/text()"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy>
                <xsl:apply-templates select="node() | @*"/>
            </xsl:copy>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
</xsl:stylesheet>

像：

<table>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value1</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value1</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value2</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1>Value2</column_1>
    <column_2></column_2>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
</row>

4

2 回答 2

0

y您可以尝试在 else 子句中将要向下传播的值保存在 <xsl:variable name="saved" select="."> 中，然后在该行中：

<xsl:with-param name="value" select="preceding::row[1]/column_1/text()"/>

改为

<xsl:with-param name="value" select="$saved"/>

根据您可能想要使用唯一变量名称的不同列的数量。

于 2013-01-04T15:33:48.963 回答
0

你几乎拥有它，但不是这个：

preceding::row[1]/column_1/text()

你需要这个：

preceding::row[column_1 != ''][1]/column_1/text()

这可以进一步简化为：

preceding::column_1[. != ''][1]

因为您需要找到包含非空白列的最后一行。

另一方面，我看不出有任何理由使用那个替换值模板。您的 XSLT 可以简化为：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output indent="yes"/>
  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="column_1">
    <xsl:copy>
      <xsl:choose>
        <xsl:when test=".=''">
          <xsl:value-of select="preceding::column_1[. != ''][1]"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates select="node() | @*"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>
于 2013-01-04T16:08:49.233 回答