haskell - Control.Monad.State API 最近是否发生了变化？

Question

作为学习练习，我正在尝试在 Haskell 中实现堆排序。我认为Statemonad 将是这样做的正确选择，因为堆非常依赖于在单个结构内移动数据（并且do符号会很有用）。此外，我希望总体上巩固我对单子的理解。

Learn You A Haskell（以及许多其他教程）中关于monad的示例，State定义为： State

newtype State s a = State { runState :: s -> (a,s) }

我应该将一个类型的函数s -> (a,s)（可能会或可能不会在其他参数中进行咖喱）传递给State值构造函数。所以我的函数看起来像这样：

pop :: Ord a => State (Heap a) a
pop = State pop'
pop' :: Ord a => Heap a -> (a, Heap a)
-- implementation of pop' goes here

push :: Ord a => a -> State (Heap a) ()
push item = State $ push' item
push' :: Ord a => a -> Heap a -> ((), Heap a)
-- implementation of push' goes here

这不会编译，出现以下错误：

Not in scope: data constructor `State'
Perhaps you meant `StateT' (imported from Control.Monad.State)

通过阅读API 文档，Control.Monad.State似乎State自从编写了这些教程以来，值构造函数已从模块中删除。作为初学者，我发现文档远非一目了然。所以我的问题是：

1. 我是否相信State值构造函数已经消失了？
2. 我应该改用什么？

Answer 1

1. 是的，它消失了，取而代之的是StateT. （Statemonad 现在是根据StateTmonad 转换器定义的。）
2. 您应该改用该state功能。

但是，我会质疑您的方法是否正确。与其担心如何State实现，不如考虑使用 do-notation 和getandput函数。

Answer 2

以下是与 State Monad 相关的书中所示示例的正确实现：

一元堆栈：

-- MonadicStack.hs (Learn You a Haskell for Great Good!)

import Control.Monad.State  

type Stack = [Int]

pop :: State Stack Int
-- The following line was wrong in the book:
-- pop = State $ \(x:xs) -> (x,xs)  
pop = do
 x:xs <- get
 put xs
 return x

push :: Int -> State Stack ()  
-- The following line was wrong in the book:
-- push a = State $ \xs -> ((),a:xs)
push a = do
 xs <- get
 put (a:xs)
 return ()

pop1 = runState pop [1..5]
push1 = runState (push 1) [2..5]

stackManip :: State Stack Int  
stackManip = do  
 push 3  
 a <- pop  
 pop  

stackManip1 = runState stackManip [5,8,2,1]  
stackManip2 = runState stackManip [1,2,3,4]  

stackStuff :: State Stack ()  
stackStuff = do  
 a <- pop  
 if a == 5  
  then push 5  
  else do  
   push 3  
   push 8  

stackStuff1 = runState stackStuff [9,0,2,1,0]  
stackStuff2 = runState stackStuff [5,4,3,2,1]

moreStack :: State Stack ()  
moreStack = do  
 a <- stackManip  
 if a == 100  
  then stackStuff  
  else return ()  

moreStack1 = runState moreStack [100,9,0,2,1,0]
moreStack2 = runState moreStack [9,0,2,1,0]

stackyStack :: State Stack ()  
stackyStack = do  
 stackNow <- get  
 if stackNow == [1,2,3]  
  then put [8,3,1]  
  else put [9,2,1]  

stackyStack1 = runState stackyStack [1,2,3]
stackyStack2 = runState stackyStack [10,20,30,40]

一元随机发生器：

-- MonadicRandomGenerator.hs (Learn You a Haskell for Great Good!)

import System.Random  
import Control.Monad.State  

randomSt :: (RandomGen g, Random a) => State g a  
-- The following line was wrong in the book:
-- randomSt = State random
randomSt = do
 gen <- get
 let (value,nextGen) = random gen
 put nextGen
 return value

randomSt1 = (runState randomSt (mkStdGen 1)) :: (Int,StdGen)
randomSt2 = (runState randomSt (mkStdGen 2)) :: (Float,StdGen)

threeCoins :: State StdGen (Bool,Bool,Bool)  
threeCoins = do  
 a <- randomSt  
 b <- randomSt  
 c <- randomSt  
 return (a,b,c)  

threeCoins1 = runState threeCoins (mkStdGen 33)
threeCoins2 = runState threeCoins (mkStdGen 2)

-- rollDie and rollNDice are not explained in the book LYAHFGG. 
-- But these functions are interesting and complementary:

rollDie :: State StdGen Int
rollDie = do 
 generator <- get
 let (value, newGenerator) = randomR (1,6) generator
 put newGenerator
 return value

rollDie1 = runState rollDie (mkStdGen 1)
rollDie2 = runState rollDie (mkStdGen 2)

rollNDice :: Int -> State StdGen [Int]
rollNDice 0 = do
 return []
rollNDice n = do
 value <- rollDie
 list <- rollNDice (n-1)
 return (value:list)

rollNDice1 = runState (rollNDice 10) (mkStdGen 1)
rollNDice2 = runState (rollNDice 20) (mkStdGen 2)

Answer 3

我认为state可以简洁地实现pop，但modify更好的是，push因为它返回单位：

import Control.Monad.State  

type Stack a = [a]

pop :: State (Stack a) a
pop = state $ \(a:as) -> (a, as)

push :: a -> State (Stack a) ()  
push a = modify (a:)

Answer 4

DESUGARED MONADIC 堆栈：

-- DesugaredMonadicStack.hs (Learn You a Haskell for Great Good!)

import Control.Monad.State  

type Stack = [Int]

pop :: State Stack Int  
pop = 
 get >>=
 \(x:xs) -> put xs >>
 return x

push :: Int -> State Stack ()
push a =
 get >>=
 \xs -> put (a:xs) >>
 return ()

pop1 = runState pop [1..5]
push1 = runState (push 1) [2..5]

stackManip :: State Stack Int  
stackManip =
 push 3 >>
 pop >>=
 \a -> pop

stackManip1 = runState stackManip [5,8,2,1]  
stackManip2 = runState stackManip [1,2,3,4]  

stackStuff :: State Stack ()  
stackStuff =
 pop >>=
 \a -> 
  if a == 5 then
   push 5
  else
   push 3 >>
   push 8

stackStuff1 = runState stackStuff [9,0,2,1,0]  
stackStuff2 = runState stackStuff [5,4,3,2,1]

moreStack :: State Stack ()  
moreStack =
 stackManip >>=
 \a ->
  if a == 100 then
   stackStuff
  else
   return ()

moreStack1 = runState moreStack [100,9,0,2,1,0]
moreStack2 = runState moreStack [9,0,2,1,0]
moreStack3 = runState moreStack [100,5,4,3,2,1]

stackyStack :: State Stack ()  
stackyStack =
 get >>=
 \stackNow ->
  if stackNow == [1,2,3] then
   put [8,3,1]
  else
   put [9,2,1]

stackyStack1 = runState stackyStack [1,2,3]
stackyStack2 = runState stackyStack [10,20,30,40] 

DESUGARED MONADIC RANDOM 生成器：

-- DesugaredMonadicRandomGenerator.hs (Learn You a Haskell for Great Good!)

import System.Random  
import Control.Monad.State  

randomSt :: (RandomGen g, Random a) => State g a  
randomSt =
 get >>=
 \gen -> 
  let (value,nextGen) = random gen
  in
   put nextGen >>
   return value

randomSt1 = (runState randomSt (mkStdGen 1)) :: (Int,StdGen)
randomSt2 = (runState randomSt (mkStdGen 2)) :: (Float,StdGen)

threeCoins :: State StdGen (Bool,Bool,Bool)
threeCoins =
 randomSt >>=
 \a -> randomSt >>=
 \b -> randomSt >>=
 \c -> return (a,b,c)

threeCoins1 = runState threeCoins (mkStdGen 33)
threeCoins2 = runState threeCoins (mkStdGen 2)

-- rollDie and rollNDice are not explained in the book LYAHFGG. 
-- But these functions are interesting and complementary:

rollDie :: State StdGen Int
rollDie =
 get >>=
 \generator -> 
  let (value, newGenerator) = randomR (1,6) generator
  in
   put newGenerator >>
   return value

rollDie1 = runState rollDie (mkStdGen 1)
rollDie2 = runState rollDie (mkStdGen 2)

rollNDice :: Int -> State StdGen [Int]
rollNDice 0 = return []
rollNDice n =
 rollDie >>=
 \value -> rollNDice (n-1) >>=
 \list -> return (value:list)

rollNDice1 = runState (rollNDice 10) (mkStdGen 1)
rollNDice2 = runState (rollNDice 20) (mkStdGen 2)