6

我有一组看起来像这样的数据

col1    col2    col3    col4
ABC1    DEF1    GHI1    cond1
ABC2    DEF2    GHI2    cond1-cond2
ABC3    DEF3    GHI3    cond2/cond1
ABC4    DEF4    GHI4    cond2 cond1
ABC5    DEF5    GHI5    cond4/cond1
ABC6    DEF6    GHI6    cond1
ABC7    DEF7    GHI7    mcond1
ABC8    DEF8    GHI8    cond2
ABC9    DEF9    GHI9    cond1 at 50
ABCa    DEFa    GHIa    con cond1
ABCb    DEFb    GHIb    no. cond1
ABCc    DEFc    GHIc    cond1 something
ABCc    DEFc    GHIc    Mcond1

我正在尝试编写几个命令来根据“col4”分离数据以获得：

  1. 一个包含字符串“cond1”的文件，在它之前或之后都有任何内容，除了“M”和“m”字母。我目前正在为此使用此命令（显然不排除 M 和 m）：

    awk 'BEGIN{IGNORECASE=1} $4 ~ /.cond1/ || $4 ~ /cond1./ ' /filepath.tab

    也请不要第 4、第 9 和第 11 行数据包含“cond1”和其他字符串之间的空格，我希望将其包含在文件中。（命令中的“.”是否包含空格？）

  2. 我写了一个命令来获取一个仅在“col4”中包含“cond1”的文件

    awk 'BEGIN{IGNORECASE=1} $4 ~ /^cond1$/ '  /filepath.tab

    尽管我在结果中发现了这 2 个错误，但大多数数据都可以正常工作：

    ABC9    DEF9    GHI9    cond1 at 50
ABCc    DEFc    GHIc    cond1 something

谁能帮我用这两个命令？谢谢。

我正在寻找不包含任何重复的 3 个文件的输出，这是一个示例： File1（包含与 cond1 的所有组合）：

col1    col2    col3    col4
ABC2    DEF2    GHI2    cond1-cond2
ABC3    DEF3    GHI3    cond2/cond1
ABC4    DEF4    GHI4    cond2 cond1
ABC5    DEF5    GHI5    cond4/cond1
ABC9    DEF9    GHI9    cond1 at 50
ABCa    DEFa    GHIa    con cond1
ABCb    DEFb    GHIb    no. cond1
ABCc    DEFc    GHIc    cond1 something

File2（仅包含 cond1）：

col1    col2    col3    col4
ABC1    DEF1    GHI1    cond1
ABC6    DEF6    GHI6    cond1

File3（包含 file1 和 file2 中未包含的任何内容）：

col1    col2    col3    col4
ABC7    DEF7    GHI7    mcond1
ABC8    DEF8    GHI8    cond2
ABCc    DEFc    GHIc    Mcond1

请注意，这 3 个文件的总行数与原始文件相同，如果这听起来相当复杂，我很抱歉，但我实际上就是这种情况。

4

3 回答 3

2

问题是第 4 列中有空格，并且您的文件未按预期格式化尝试awk -F'\t' {print $4} file并注意它可能不是您所期望的。

首先将文件转换为 CSV 格式sed

$ sed 's/\s\+/,/;s/\s\+/,/;s/\s\+/,/;' file
col1,col2,col3,col4
ABC1,DEF1,GHI1,cond1
ABC2,DEF2,GHI2,cond1-cond2
ABC3,DEF3,GHI3,cond2/cond1
ABC4,DEF4,GHI4,cond2 cond1
ABC5,DEF5,GHI5,cond4/cond1
ABC6,DEF6,GHI6,cond1
ABC7,DEF7,GHI7,mcond1
ABC8,DEF8,GHI8,cond2
ABC9,DEF9,GHI9,cond1 at 50
ABCa,DEFa,GHIa,con cond1
ABCb,DEFb,GHIb,no. cond1
ABCc,DEFc,GHIc,cond1 something
ABCc,DEFc,GHIc,Mcond1

这只会将前 3 个空白组转换为逗号，从而根据需要留下 col4。要将更改存储在文件中，请使用以下-i选项：

sed -i 's/\s\+/,/;s/\s\+/,/;s/\s\+/,/;' file

,现在可以使用字段分隔符。

awk 'BEGIN{FS=",";OFS="\t"} NR==1{print $1,$2,$3,$4} $4~/cond1./|| $4~/[^mM]cond1/{print $1,$2,$3,$4}' file
col1    col2    col3    col4
ABC2    DEF2    GHI2    cond1-cond2
ABC3    DEF3    GHI3    cond2/cond1
ABC4    DEF4    GHI4    cond2 cond1
ABC5    DEF5    GHI5    cond4/cond1
ABC9    DEF9    GHI9    cond1 at 50
ABCa    DEFa    GHIa    con cond1
ABCb    DEFb    GHIb    no. cond1
ABCc    DEFc    GHIc    cond1 something

$ awk 'BEGIN{FS=",";OFS="\t"} NR==1{print $1,$2,$3,$4} $4~/^cond1$/{print $1,$2,$3,$4}' file 
col1    col2    col3    col4
ABC1    DEF1    GHI1    cond1
ABC6    DEF6    GHI6    cond1

$ awk 'BEGIN{FS=",";OFS="\t"} $4!~/cond1/ || $4~/[Mm]cond1/{print $1,$2,$3,$4}' file
col1    col2    col3    col4
ABC7    DEF7    GHI7    mcond1
ABC8    DEF8    GHI8    cond2
ABCc    DEFc    GHIc    Mcond1

只需重定向以保存新文件awk '{...}' > file1。

于 2013-01-04T10:49:16.087 回答
1

由于您的字段是制表符分隔的，请FS="\t"在BEGIN块中使用。你的条件也不合适。所以我改变了它。

awk 'BEGIN{IGNORECASE=1; FS="\t"; } $4 ~ /cond1/ && $4 !~ /mcond1|cond1m/' data
于 2013-01-04T10:38:51.267 回答
1

您只需通过一次即可完成任务。像这样运行：

awk -f script.awk file

内容script.awk：

BEGIN {
    FS="\t"
}

NR==1 {
    r=$0
    next
}

{
    i = ($4 == "cond1" ? 2 : ($4 ~ /cond1/ && $4 !~ /[Mm]cond1/ ? 1 : 3))
    print (!a[i]++ ? r ORS : "") $0 > "file" i ".txt"
}

结果grep . file[1-3].txt：

file1.txt:col1  col2    col3    col4
file1.txt:ABC2  DEF2    GHI2    cond1-cond2
file1.txt:ABC3  DEF3    GHI3    cond2/cond1
file1.txt:ABC4  DEF4    GHI4    cond2 cond1
file1.txt:ABC5  DEF5    GHI5    cond4/cond1
file1.txt:ABC9  DEF9    GHI9    cond1 at 50
file1.txt:ABCa  DEFa    GHIa    con cond1
file1.txt:ABCb  DEFb    GHIb    no. cond1
file1.txt:ABCc  DEFc    GHIc    cond1 something
file2.txt:col1  col2    col3    col4
file2.txt:ABC1  DEF1    GHI1    cond1
file2.txt:ABC6  DEF6    GHI6    cond1
file3.txt:col1  col2    col3    col4
file3.txt:ABC7  DEF7    GHI7    mcond1
file3.txt:ABC8  DEF8    GHI8    cond2
file3.txt:ABCc  DEFc    GHIc    Mcond1

或者，这是单线：

awk -F "\t" 'NR==1 { r=$0; next } { i = ($4 == "cond1" ? 2 : ($4 ~ /cond1/ && $4 !~ /[Mm]cond1/ ? 1 : 3)); print (!a[i]++ ? r ORS : "") $0 > "file" i ".txt" }' file
于 2013-01-05T04:45:31.617 回答