1

我有 ObjectList 容器，我想添加一个内部迭代器（访问者模式）事实上我正在尝试确定我的列表中的重复项..

一个样本： http: //pastebin.com/pjeWq2uN

这段代码提供了我想要实现的洞察力..

TFindDuplicatesMethod = procedure(s1, s2: string) of object;

TPersonList = class(TObjectList)
public
  procedure Iterate(pMethode: TFindDuplicatesMethod)
end;

procedure TPersonList.Iterate(pMethode: TFindDuplicatesMethod)
var
  i: Integer;
begin
  for i := 0 to Count - 1 do
  pMethode(TMyClass(Items[i]).S1, {But i don't have the second parameter because
                               it comes from outside of PersonList Ex: OpenDialog.Files[i]})
end;

function FindDuplicate(S1, S2: string): Boolean;
begin
  Result := False;
  if S1 = S2 then
  Result := True;
end;

begin
  Files.Iterate(FindDuplicates(S1, S2));
end;

我想知道 OOP 如何解决这样的问题。

提前致谢...

4

1 回答 1

12

好的，正如我们在评论中发现的，我们有 2 个任务：

  1. 如何查找是否TObjectList已经包含一个项目（所以新项目是重复的）
  2. 如何管理文件图标TImageList以减少内存使用并仅存储唯一图标。

正如我在评论中提到的，您应该在单独的线程中询问您的第二个问题，但我建议您添加新的文件图标取决于新的文件 mime 类型，而不是二进制图标数据。在这里你必须创建文件类型字典，确定文件类型等等。

中的重复项怎么办TObjectList？您可能知道，有generic- 的TObjectList实现TObjectsList<T>。在您的示例中，您可以定义TPersonList为TObjectList<TPerson>，因此items属性始终返回TPerson对象实例。

现在，带有列表的通用任务 - 列表排序。看看Sort()方法TObjectList<T>/TList。它有2个重载方法。其中一个是默认的，第二个是Comparer作为参数。实际上，第一种方法也使用了一个比较器——默认比较器。所以比较器是IComparer<T>接口的实现，它有唯一的方法 - function Compare(l,r : T):integer; 通常，在调用该方法之前，您会在运行时将此排序比较器定义为匿名Sort()方法。使用匿名方法，您总是知道如何比较两个T类型的对象，然后您可以确定它们中的哪一个比其他对象“更大”，并且应该是列表中的第一个。

所以你在列表中搜索重复项时遇到的情况相同。但现在您必须确定 2 个对象是否相等。

让我们假设您有personList : TPersonList包含TPerson实例。例如，每个人都有姓名、姓氏、出生日期和身份证。当然，默认比较器对如何比较 2 人一无所知。但是您可以提供新的比较器知道。例如，假设 2 个对象相等，如果它们的 ID 相等；

    TPerson = class(TObject)
      strict private
        FName : string;
        FSurname : string;
        FDateOfBirth : TDateTime;
        FId : string;   {passport number or something else}
      public
        constructor Create(aID : string; aDoB : TDateTime);

        property Name : string read FName write FName;
        property Surname : string read FSurname write FSurname;
        property DateOfBirth : TDateTime read FDateOfBirth;
        property ID : string read FId;
    end;


    TPersonList = class(TObjectList<TPerson>)
      public
        constructor Create();
    end;

TPerson构造函数是通常的：

constructor TPerson.Create(aID: string; aDoB: TDateTime);
begin
    inherited Create();
    FID := aId;
    FDateOfBirth := aDoB;
end;

现在我们必须编写TPersonList构造函数。如您所见，TObejctList构造函数几乎没有重载。其中之一有Comparer参数。它保存aComparer到FComparer现场。现在，看看Contains方法。它发现列表是否已经包含对象。它使用IndexOf方法。因此，如果返回的 index = 0 则列表包含我们的对象。

所以现在我们的任务是在TPersonList构造函数中定义新的比较器。我们应该定义比较方法，然后创建比较器对象并将其传递给列表构造器。

constructor TPersonList.Create();
var comparer : IComparer<TPerson>;
    comparison : TComparison<TPerson>;
begin
    comparison := function(const l,r : TPerson):integer
                  begin
                    if l.ID = r.id then exit(0)
                    else if l.ID > r.ID then exit(-1)
                    else exit(1);
                  end;

    comparer := TComparer<TPerson>.Construct(comparison);

    inherited Create(comparer);
end;

为了测试我们的代码，让我们添加一些人到列表中。

procedure TForm2.FormCreate(Sender: TObject);
var persons : TPersonList;

    function AddPerson(id : string; date : TDateTime):boolean;
    var p : TPerson;
    begin
        p := TPerson.Create(id, date);

        result := not persons.Contains(p);

        if result then
            persons.Add(p)
        else begin
            ShowMessage('list already contains person with id = ' + id);
            p.Free();
        end;
    end;
begin
    persons := TPersonList.Create();
    try
        AddPerson('1', StrToDate('01.01.2000'));
        AddPerson('2', StrToDate('01.01.2000'));
        AddPerson('3', StrToDate('01.01.2000'));
        AddPerson('2', StrToDate('01.01.2000')); // we will get message here.
    finally
        persons.Free();
    end;
end;

因此，这是确定TList（或其后代）是否包含对象的常用方法。

于 2013-01-04T15:26:18.017 回答